Initial commit

scripting/include/smlib/arrays.inc

@@ -0,0 +1,157 @@
+#if defined _smlib_array_included
+	#endinput
+#endif
+#define _smlib_array_included
+
+#include <sourcemod>
+
+/**
+ * Returns the index for the first occurance of the given value.
+ * If the value cannot be found, -1 will be returned.
+ *
+ * @param array			Static Array.
+ * @param size			Size of the Array.
+ * @param value			Value to search for.
+ * @param start			Optional: Offset where to start (0 - (size-1)).
+ * @return				Array index, or -1 if the value couldn't be found.
+ */
+stock int Array_FindValue(const any[] array, int size, any value, int start=0)
+{
+	if (start < 0) {
+		start = 0;
+	}
+
+	for (int i=start; i < size; i++) {
+
+		if (array[i] == value) {
+			return i;
+		}
+	}
+
+	return -1;
+}
+
+/**
+ * Searchs for the first occurance of a string in the array.
+ * If the value cannot be located, -1 will be returned.
+ *
+ * @param array			Static Array.
+ * @param size			Size of the Array.
+ * @param value			String to search for.
+ * @param start			Optional: Offset where to start(0 - (size-1)).
+ * @return				Array index, or -1 if the value couldn't be found.
+ */
+stock int Array_FindString(const char[][] array, int size, const char[] str, bool caseSensitive=true, int start=0)
+{
+	if (start < 0) {
+		start = 0;
+	}
+
+	for (int i=start; i < size; i++) {
+
+		if (StrEqual(array[i], str, caseSensitive)) {
+			return i;
+		}
+	}
+
+	return -1;
+}
+
+/**
+ * Returns the Index of the Lowest value in the array
+ *
+ * @param array			Static Array.
+ * @param size			Size of the Array.
+ * @param start			Optional: Offset where to start (0 - (size-1)).
+ * @return				Array index.
+ */
+stock int Array_FindLowestValue(const any[] array, int size, int start=0)
+{
+	if (start < 0) {
+		start = 0;
+	}
+
+	any value = array[start];
+	any tempValue;
+	int x = start;
+
+	for (int i=start; i < size; i++) {
+
+		tempValue = array[i];
+
+		if (tempValue < value) {
+			value = tempValue;
+			x = i;
+		}
+
+	}
+
+	return x;
+}
+
+/**
+ * Returns the Index of the Highest value in the array
+ *
+ * @param array			Static Array.
+ * @param size			Size of the Array.
+ * @param start			Optional: Offset where to start (0 - (size-1)).
+ * @return				Array index.
+ */
+stock int Array_FindHighestValue(const any[] array, int size, int start=0)
+{
+	if (start < 0) {
+		start = 0;
+	}
+
+	any value = array[start];
+	any tempValue;
+	int x = start;
+
+	for (int i=start; i < size; i++) {
+
+		tempValue = array[i];
+
+		if (tempValue > value) {
+			value = tempValue;
+			x = i;
+		}
+
+	}
+
+	return x;
+}
+
+/**
+ * Fills an array with a given value in a 1 dimensional static array.
+ * You can specify the amount of cells to be written.
+ *
+ * @param array			Static Array.
+ * @param size			Number of cells to write (eg. the array's size)
+ * @param value			Fill value.
+ * @param start			Optional: Offset where to start (0 - (size-1)).
+ */
+stock void Array_Fill(any[] array, int size, any value, int start=0)
+{
+	if (start < 0) {
+		start = 0;
+	}
+
+	for (int i=start; i < size; i++) {
+		array[i] = value;
+	}
+}
+
+/**
+ * Copies a 1 dimensional static array.
+ *
+ * @param array			Static Array to copy from.
+ * @param newArray		New Array to copy to.
+ * @param size			Size of the array (or number of cells to copy)
+ * @noreturn
+ */
+stock void Array_Copy(const any[] array, any[] newArray, int size)
+{
+	for (int i=0; i < size; i++) {
+		newArray[i] = array[i];
+	}
+}

scripting/include/smlib/colors.inc

@@ -0,0 +1,575 @@
+#if defined _smlib_colors_included
+	#endinput
+#endif
+#define _smlib_colors_included
+
+#include <sourcemod>
+#include <smlib/arrays>
+#include <smlib/teams>
+
+#define CHATCOLOR_NOSUBJECT -2
+#define SMLIB_COLORS_GAMEDATAFILE "smlib_colors.games"
+
+enum ChatColorSubjectType
+{
+	ChatColorSubjectType_none       = -3,
+
+	// Subject/Team colors
+	ChatColorSubjectType_player     = -2,
+	ChatColorSubjectType_undefined	= -1,
+	ChatColorSubjectType_world      = 0
+	// Anything higher is a specific team
+}
+
+enum struct ChatColorInfo
+{
+	int ChatColorInfo_Code;
+	int ChatColorInfo_Alternative;
+	bool ChatColorInfo_Supported;
+	ChatColorSubjectType ChatColorInfo_SubjectType;
+}
+
+enum ChatColor
+{
+	ChatColor_Normal,
+	ChatColor_Orange,
+	ChatColor_Red,
+	ChatColor_RedBlue,
+	ChatColor_Blue,
+	ChatColor_BlueRed,
+	ChatColor_Team,
+	ChatColor_Lightgreen,
+	ChatColor_Gray,
+	ChatColor_Green,
+	ChatColor_Olivegreen,
+	ChatColor_Black,
+	ChatColor_MAXCOLORS
+}
+
+static char chatColorTags[][] = {
+	"N",    // Normal
+	"O",    // Orange
+	"R",    // Red
+	"RB",   // Red, Blue
+	"B",    // Blue
+	"BR",   // Blue, Red
+	"T",    // Team
+	"L",    // Light green
+	"GRA",  // Gray
+	"G",    // Green
+	"OG",   // Olive green
+	"BLA"   // Black
+};
+
+static char chatColorNames[][] = {
+	"normal",               // Normal
+	"orange",               // Orange
+	"red",                  // Red
+	"redblue",              // Red, Blue
+	"blue",                 // Blue
+	"bluered",              // Blue, Red
+	"team",                 // Team
+	"lightgreen",           // Light green
+	"gray",                 // Gray
+	"green",                // Green
+	"olivegreen",           // Olive green
+	"black"                 // Black
+};
+
+static ChatColorInfo chatColorInfo[ChatColor_MAXCOLORS];
+
+static bool checkTeamPlay               = false;
+static ConVar mp_teamplay               = null;
+static bool isSayText2_supported	= true;
+static int chatSubject                  = CHATCOLOR_NOSUBJECT;
+
+/**
+ * Sets the subject (a client) for the chat color parser.
+ * Call this before Color_ParseChatText() or Client_PrintToChat().
+ *
+ * @param client			Client Index/Subject
+ */
+stock void Color_ChatSetSubject(int client)
+{
+	chatSubject = client;
+}
+
+/**
+ * Gets the subject used for the chat color parser.
+ *
+ * @return					Client Index/Subject, or CHATCOLOR_NOSUBJECT if none
+ */
+stock int Color_ChatGetSubject()
+{
+	return chatSubject;
+}
+
+/**
+ * Clears the subject used for the chat color parser.
+ * Call this after Color_ParseChatText().
+ */
+stock void Color_ChatClearSubject()
+{
+	chatSubject = CHATCOLOR_NOSUBJECT;
+}
+
+/**
+ * Parses a chat string and converts all color tags to color codes.
+ * This is a very powerful function that works recursively over the color information
+ * table. The support colors are hardcoded, but can be overriden for each game by
+ * creating the file gamedata/smlib_colors.games.txt.
+ *
+ * @param str                           Chat String
+ * @param subject                       Output Buffer
+ * @param size                          Output Buffer size
+ * @return                              Returns a value for the subject
+ */
+stock int Color_ParseChatText(const char[] str, char[] buffer, int size)
+{
+	bool inBracket = false;
+	int x, x_buf, x_tag;
+	int subject = CHATCOLOR_NOSUBJECT;
+
+	char sTag[10]         = "";     // This should be able to hold "\x08RRGGBBAA"\0
+	char colorCode[10]    = "";     // This should be able to hold "\x08RRGGBBAA"\0
+	char currentColor[10] = "\x01"; // Initialize with normal color
+
+	size--;
+
+	// Every chat message has to start with a
+	// color code, otherwise it will ignore all colors.
+	buffer[x_buf++] = '\x01';
+
+	while (str[x] != '\0') {
+
+		if (size == x_buf) {
+			break;
+		}
+
+		char character = str[x++];
+
+		if (inBracket) {
+			// We allow up to 9 characters in the tag (#RRGGBBAA)
+			if (character == '}' || x_tag > 9) {
+				inBracket   = false;
+				sTag[x_tag] = '\0';
+				x_tag       = 0;
+
+				if (character == '}') {
+					Color_TagToCode(sTag, subject, colorCode);
+
+					if (colorCode[0] == '\0') {
+						// We got an unknown tag, ignore this
+						// and forward it to the buffer.
+
+						// Terminate buffer with \0 so Format can handle it.
+						buffer[x_buf] = '\0';
+						x_buf = Format(buffer, size, "%s{%s}", buffer, sTag);
+
+						// We 'r done here
+						continue;
+					}
+					else if (!StrEqual(colorCode, currentColor)) {
+						// If we are already using this color,
+						// we don't need to set it again.
+
+						// Write the color code to our buffer.
+						// x_buf will be increased by the number of cells written.
+						x_buf += strcopy(buffer[x_buf], size - x_buf, colorCode);
+
+						// Remember the current color.
+						strcopy(currentColor, sizeof(currentColor), colorCode);
+					}
+				}
+				else {
+					// If the tag character limit exceeds 9,
+					// we have to do something.
+
+					// Terminate buffer with \0 so Format can handle it.
+					buffer[x_buf] = '\0';
+					x_buf = Format(buffer, size, "%s{%s%c", buffer, sTag, character);
+				}
+			}
+			else if (character == '{' && !x_tag) {
+				buffer[x_buf++] = '{';
+				inBracket = false;
+			}
+			else {
+				sTag[x_tag++] = character;
+			}
+		}
+		else if (character == '{') {
+			inBracket = true;
+		}
+		else {
+			buffer[x_buf++] = character;
+		}
+	}
+
+	// Write remaining text to the buffer,
+	// if we have been inside brackets.
+	if (inBracket) {
+		buffer[x_buf] = '\0';
+		x_buf = Format(buffer, size, "%s{%s", buffer, sTag);
+	}
+
+	buffer[x_buf] = '\0';
+
+	return subject;
+}
+
+/**
+ * Converts a chat color tag to its code character.
+ *
+ * @param tag				Color Tag String.
+ * @param subject			Subject variable to pass
+ * @param result            The result as character sequence (string). This will be \0 if the tag is unkown.
+ */
+stock void Color_TagToCode(const char[] tag, int &subject=-1, char result[10])
+{
+	// Check if the tag starts with a '#'.
+	// We will handle it has RGB(A)-color code then.
+	if (tag[0] == '#') {
+		int length_tag = strlen(tag);
+		switch (length_tag - 1) {
+			// #RGB      -> \07RRGGBB
+			case 3: {
+				FormatEx(
+					result, sizeof(result), "\x07%c%c%c%c%c%c",
+					tag[1], tag[1], tag[2], tag[2], tag[3], tag[3]
+				);
+			}
+			// #RGBA     -> \08RRGGBBAA
+			case 4: {
+				FormatEx(
+					result, sizeof(result), "\x08%c%c%c%c%c%c%c%c",
+					tag[1], tag[1], tag[2], tag[2], tag[3], tag[3], tag[4], tag[4]
+				);
+			}
+			// #RRGGBB   -> \07RRGGBB
+			case 6: {
+				FormatEx(result, sizeof(result), "\x07%s", tag[1]);
+			}
+			// #RRGGBBAA -> \08RRGGBBAA
+			case 8: {
+				FormatEx(result, sizeof(result), "\x08%s", tag[1]);
+			}
+			default: {
+				result[0] = '\0';
+			}
+		}
+
+		return;
+	}
+	else {
+		// Try to handle this string as color name
+		int n = Array_FindString(chatColorTags, sizeof(chatColorTags), tag);
+
+		// Check if this tag is invalid
+		if (n == -1) {
+			result[0] = '\0';
+			return;
+		}
+
+		// Check if the color is actually supported 'n stuff.
+		Color_GetChatColorInfo(n, subject);
+
+		result[0] = chatColorInfo[n].ChatColorInfo_Code;
+		result[1] = '\0';
+	}
+
+	return;
+}
+
+/**
+ * Strips all color control characters in a string.
+ * The Output buffer can be the same as the input buffer.
+ * Original code by Psychonic, thanks.
+ *
+ * @param input				Input String.
+ * @param output			Output String.
+ * @param size				Max Size of the Output string
+ */
+stock void Color_StripFromChatText(const char[] input, char[] output, int size)
+{
+	int x = 0;
+	for (int i=0; input[i] != '\0'; i++) {
+
+		if (x+1 == size) {
+			break;
+		}
+
+		char character = input[i];
+
+		if (character > 0x08) {
+			output[x++] = character;
+		}
+	}
+
+	output[x] = '\0';
+}
+
+/**
+ * Checks the gamename and sets default values.
+ * For example if some colors are supported, or
+ * if a game uses another color code for a specific color.
+ * All those hardcoded default values can be overriden in
+ * smlib's color gamedata file.
+ */
+static stock void Color_ChatInitialize()
+{
+	static bool initialized = false;
+
+	if (initialized) {
+		return;
+	}
+
+	initialized = true;
+	
+	// Normal
+	chatColorInfo[ChatColor_Normal].ChatColorInfo_Code = '\x01';
+	chatColorInfo[ChatColor_Normal].ChatColorInfo_Alternative = -1; /* None */
+	chatColorInfo[ChatColor_Normal].ChatColorInfo_Supported = true;
+	chatColorInfo[ChatColor_Normal].ChatColorInfo_SubjectType = ChatColorSubjectType_none;
+	
+	// Orange
+	chatColorInfo[ChatColor_Orange].ChatColorInfo_Code = '\x01';
+	chatColorInfo[ChatColor_Orange].ChatColorInfo_Alternative = 0; /* None */
+	chatColorInfo[ChatColor_Orange].ChatColorInfo_Supported = true;
+	chatColorInfo[ChatColor_Orange].ChatColorInfo_SubjectType = ChatColorSubjectType_none;
+	
+	// Red
+	chatColorInfo[ChatColor_Red].ChatColorInfo_Code = '\x03';
+	chatColorInfo[ChatColor_Red].ChatColorInfo_Alternative = 9; /* Green */
+	chatColorInfo[ChatColor_Red].ChatColorInfo_Supported = true;
+	chatColorInfo[ChatColor_Red].ChatColorInfo_SubjectType = view_as<ChatColorSubjectType>(2);
+	
+	// Red, Blue
+	chatColorInfo[ChatColor_RedBlue].ChatColorInfo_Code = '\x03';
+	chatColorInfo[ChatColor_RedBlue].ChatColorInfo_Alternative = 4; /* Blue */
+	chatColorInfo[ChatColor_RedBlue].ChatColorInfo_Supported = true;
+	chatColorInfo[ChatColor_RedBlue].ChatColorInfo_SubjectType = view_as<ChatColorSubjectType>(2);
+	
+	// Blue
+	chatColorInfo[ChatColor_Blue].ChatColorInfo_Code = '\x03';
+	chatColorInfo[ChatColor_Blue].ChatColorInfo_Alternative = 9; /* Green */
+	chatColorInfo[ChatColor_Blue].ChatColorInfo_Supported = true;
+	chatColorInfo[ChatColor_Blue].ChatColorInfo_SubjectType = view_as<ChatColorSubjectType>(3);
+	
+	// Blue, Red
+	chatColorInfo[ChatColor_BlueRed].ChatColorInfo_Code = '\x03';
+	chatColorInfo[ChatColor_BlueRed].ChatColorInfo_Alternative = 2; /* Red */
+	chatColorInfo[ChatColor_BlueRed].ChatColorInfo_Supported = true;
+	chatColorInfo[ChatColor_BlueRed].ChatColorInfo_SubjectType = view_as<ChatColorSubjectType>(3);
+	
+	// Team
+	chatColorInfo[ChatColor_Team].ChatColorInfo_Code = '\x03';
+	chatColorInfo[ChatColor_Team].ChatColorInfo_Alternative = 9; /* Green */
+	chatColorInfo[ChatColor_Team].ChatColorInfo_Supported = true;
+	chatColorInfo[ChatColor_Team].ChatColorInfo_SubjectType = ChatColorSubjectType_player;
+	
+	// Light green
+	chatColorInfo[ChatColor_Lightgreen].ChatColorInfo_Code = '\x03';
+	chatColorInfo[ChatColor_Lightgreen].ChatColorInfo_Alternative = 9; /* Green */
+	chatColorInfo[ChatColor_Lightgreen].ChatColorInfo_Supported = true;
+	chatColorInfo[ChatColor_Lightgreen].ChatColorInfo_SubjectType = ChatColorSubjectType_world;
+
+	// Gray
+	chatColorInfo[ChatColor_Gray].ChatColorInfo_Code = '\x03';
+	chatColorInfo[ChatColor_Gray].ChatColorInfo_Alternative = 9; /* Green */
+	chatColorInfo[ChatColor_Gray].ChatColorInfo_Supported = true;
+	chatColorInfo[ChatColor_Gray].ChatColorInfo_SubjectType = ChatColorSubjectType_undefined;
+
+	// Green
+	chatColorInfo[ChatColor_Green].ChatColorInfo_Code = '\x04';
+	chatColorInfo[ChatColor_Green].ChatColorInfo_Alternative = 0; /* Normal*/
+	chatColorInfo[ChatColor_Green].ChatColorInfo_Supported = true;
+	chatColorInfo[ChatColor_Green].ChatColorInfo_SubjectType = ChatColorSubjectType_none;
+
+	// Olive green
+	chatColorInfo[ChatColor_Olivegreen].ChatColorInfo_Code = '\x05';
+	chatColorInfo[ChatColor_Olivegreen].ChatColorInfo_Alternative = 9; /* Green */
+	chatColorInfo[ChatColor_Olivegreen].ChatColorInfo_Supported = true;
+	chatColorInfo[ChatColor_Olivegreen].ChatColorInfo_SubjectType = ChatColorSubjectType_none;
+
+	// Black
+	chatColorInfo[ChatColor_Black].ChatColorInfo_Code = '\x06';
+	chatColorInfo[ChatColor_Black].ChatColorInfo_Alternative = 9; /* Green */
+	chatColorInfo[ChatColor_Black].ChatColorInfo_Supported = true;
+	chatColorInfo[ChatColor_Black].ChatColorInfo_SubjectType = ChatColorSubjectType_none;
+
+	char gameFolderName[PLATFORM_MAX_PATH];
+	GetGameFolderName(gameFolderName, sizeof(gameFolderName));
+
+	chatColorInfo[ChatColor_Black].ChatColorInfo_Supported          = false;
+
+	if (strncmp(gameFolderName, "left4dead", 9, false) != 0 &&
+		!StrEqual(gameFolderName, "cstrike", false) &&
+		!StrEqual(gameFolderName, "tf", false))
+	{
+		chatColorInfo[ChatColor_Lightgreen].ChatColorInfo_Supported = false;
+		chatColorInfo[ChatColor_Gray].ChatColorInfo_Supported       = false;
+	}
+
+	if (StrEqual(gameFolderName, "tf", false)) {
+		chatColorInfo[ChatColor_Black].ChatColorInfo_Supported      = true;
+
+		chatColorInfo[ChatColor_Gray].ChatColorInfo_Code            = '\x01';
+		chatColorInfo[ChatColor_Gray].ChatColorInfo_SubjectType     = ChatColorSubjectType_none;
+	}
+	else if (strncmp(gameFolderName, "left4dead", 9, false) == 0) {
+		chatColorInfo[ChatColor_Red].ChatColorInfo_SubjectType      = view_as<ChatColorSubjectType>(3);
+		chatColorInfo[ChatColor_RedBlue].ChatColorInfo_SubjectType  = view_as<ChatColorSubjectType>(3);
+		chatColorInfo[ChatColor_Blue].ChatColorInfo_SubjectType     = view_as<ChatColorSubjectType>(2);
+		chatColorInfo[ChatColor_BlueRed].ChatColorInfo_SubjectType  = view_as<ChatColorSubjectType>(2);
+
+		chatColorInfo[ChatColor_Orange].ChatColorInfo_Code          = '\x04';
+		chatColorInfo[ChatColor_Green].ChatColorInfo_Code           = '\x05';
+	}
+	else if (StrEqual(gameFolderName, "hl2mp", false)) {
+		chatColorInfo[ChatColor_Red].ChatColorInfo_SubjectType      = view_as<ChatColorSubjectType>(3);
+		chatColorInfo[ChatColor_RedBlue].ChatColorInfo_SubjectType  = view_as<ChatColorSubjectType>(3);
+		chatColorInfo[ChatColor_Blue].ChatColorInfo_SubjectType     = view_as<ChatColorSubjectType>(2);
+		chatColorInfo[ChatColor_BlueRed].ChatColorInfo_SubjectType  = view_as<ChatColorSubjectType>(2);
+		chatColorInfo[ChatColor_Black].ChatColorInfo_Supported      = true;
+
+		checkTeamPlay												= true;
+	}
+	else if (StrEqual(gameFolderName, "dod", false)) {
+		chatColorInfo[ChatColor_Gray].ChatColorInfo_Code            = '\x01';
+		chatColorInfo[ChatColor_Gray].ChatColorInfo_SubjectType     = ChatColorSubjectType_none;
+
+		chatColorInfo[ChatColor_Black].ChatColorInfo_Supported      = true;
+		chatColorInfo[ChatColor_Orange].ChatColorInfo_Supported     = false;
+	}
+
+	if (GetUserMessageId("SayText2") == INVALID_MESSAGE_ID) {
+		isSayText2_supported = false;
+	}
+
+	char path_gamedata[PLATFORM_MAX_PATH];
+	BuildPath(Path_SM, path_gamedata, sizeof(path_gamedata), "gamedata/%s.txt", SMLIB_COLORS_GAMEDATAFILE);
+
+	if (FileExists(path_gamedata)) {
+		Handle gamedata = INVALID_HANDLE;
+
+		if ((gamedata = LoadGameConfigFile(SMLIB_COLORS_GAMEDATAFILE)) != INVALID_HANDLE) {
+
+			char keyName[32], buffer[6];
+
+			for (int i=0; i < sizeof(chatColorNames); i++) {
+
+				Format(keyName, sizeof(keyName), "%s_code",			chatColorNames[i]);
+				if (GameConfGetKeyValue(gamedata, keyName, buffer, sizeof(buffer))) {
+					chatColorInfo[i].ChatColorInfo_Code             = StringToInt(buffer);
+				}
+
+				Format(keyName, sizeof(keyName), "%s_alternative",	chatColorNames[i]);
+				if (GameConfGetKeyValue(gamedata, keyName, buffer, sizeof(buffer))) {
+					chatColorInfo[i].ChatColorInfo_Alternative      = buffer[0];
+				}
+
+				Format(keyName, sizeof(keyName), "%s_supported",	chatColorNames[i]);
+				if (GameConfGetKeyValue(gamedata, keyName, buffer, sizeof(buffer))) {
+					chatColorInfo[i].ChatColorInfo_Supported        = StrEqual(buffer, "true");
+				}
+
+				Format(keyName, sizeof(keyName), "%s_subjecttype",	chatColorNames[i]);
+				if (GameConfGetKeyValue(gamedata, keyName, buffer, sizeof(buffer))) {
+					chatColorInfo[i].ChatColorInfo_SubjectType      = view_as<ChatColorSubjectType>(StringToInt(buffer));
+				}
+			}
+
+			if (GameConfGetKeyValue(gamedata, "checkteamplay", buffer, sizeof(buffer))) {
+				checkTeamPlay = StrEqual(buffer, "true");
+			}
+
+			CloseHandle(gamedata);
+		}
+	}
+
+	mp_teamplay = FindConVar("mp_teamplay");
+}
+
+/**
+ * Checks if the passed color index is actually supported
+ * for the current game. If not, the index will be overwritten
+ * The color resolving works recursively until a valid color is found.
+ *
+ * @param index
+ * @param subject A client index or CHATCOLOR_NOSUBJECT
+ */
+static stock int Color_GetChatColorInfo(int &index, int &subject=CHATCOLOR_NOSUBJECT)
+{
+	Color_ChatInitialize();
+
+	if (index == -1) {
+		index = 0;
+	}
+
+	while (!chatColorInfo[index].ChatColorInfo_Supported) {
+
+		int alternative = chatColorInfo[index].ChatColorInfo_Alternative;
+
+		if (alternative == -1) {
+			index = 0;
+			break;
+		}
+
+		index = alternative;
+	}
+
+	if (index == -1) {
+		index = 0;
+	}
+
+	int newSubject = CHATCOLOR_NOSUBJECT;
+	ChatColorSubjectType type = chatColorInfo[index].ChatColorInfo_SubjectType;
+
+	switch (type) {
+		case ChatColorSubjectType_none: {
+		}
+		case ChatColorSubjectType_player: {
+			newSubject = chatSubject;
+		}
+		case ChatColorSubjectType_undefined: {
+			newSubject = -1;
+		}
+		case ChatColorSubjectType_world: {
+			newSubject = 0;
+		}
+		default: {
+
+			if (!checkTeamPlay || mp_teamplay.BoolValue) {
+
+				if (subject > 0 && subject <= MaxClients) {
+
+					if (GetClientTeam(subject) == view_as<int>(type)) {
+						newSubject = subject;
+					}
+				}
+				else if (subject == CHATCOLOR_NOSUBJECT) {
+					int client = Team_GetAnyClient(view_as<int>(type));
+
+					if (client != -1) {
+						newSubject = client;
+					}
+				}
+			}
+		}
+	}
+
+	if (type > ChatColorSubjectType_none &&
+		((subject != CHATCOLOR_NOSUBJECT && subject != newSubject) || newSubject == CHATCOLOR_NOSUBJECT || !isSayText2_supported))
+	{
+		index = chatColorInfo[index].ChatColorInfo_Alternative;
+		newSubject = Color_GetChatColorInfo(index, subject);
+	}
+
+	// Only set the subject if there is no subject set already.
+	if (subject == CHATCOLOR_NOSUBJECT) {
+		subject = newSubject;
+	}
+
+	return newSubject;
+}

scripting/include/smlib/concommands.inc

@@ -0,0 +1,45 @@
+#if defined _smlib_concommands_included
+	#endinput
+#endif
+#define _smlib_concommands_included
+
+#include <sourcemod>
+#include <smlib/clients>
+
+/**
+ * Checks if a ConCommand has one or more flags set.
+ *
+ * @param    command        ConCommand name.
+ * @param    flags        Flags to check.
+ * @return                True if flags are set, false otherwise.
+ */
+stock bool ConCommand_HasFlags(const char[] command, int flags)
+{
+    return GetCommandFlags(command) & flags > 0;
+}
+
+/**
+ * Adds one or more flags to a ConCommand.
+ *
+ * @param    command        ConCommand name.
+ * @param    flags        Flags to add.
+ */
+stock void ConCommand_AddFlags(const char[] command, int flags)
+{
+    int newFlags = GetCommandFlags(command);
+    newFlags |= flags;
+    SetCommandFlags(command, newFlags);
+}
+
+/**
+ * Removes one ore more flags from a ConCommand.
+ *
+ * @param    command        ConCommand name.
+ * @param    flags        Flags to remove
+ */
+stock void ConCommand_RemoveFlags(const char[] command, int flags)
+{
+    int newFlags = GetCommandFlags(command);
+    newFlags &= ~flags;
+    SetCommandFlags(command, newFlags);
+}

scripting/include/smlib/convars.inc

@@ -0,0 +1,71 @@
+#if defined _smlib_convars_included
+	#endinput
+#endif
+#define _smlib_convars_included
+
+#include <sourcemod>
+
+/**
+ * Checks if a ConVar has one or more flags set.
+ *
+ * @param	convar		ConVar Handle.
+ * @param	flags		Flags to check.
+ * @return				True if flags are set, false otherwise.
+ */
+stock bool Convar_HasFlags(ConVar convar, int flags)
+{
+	return convar.Flags & flags > 0;
+}
+
+/**
+ * Adds one or more flags to a ConVar.
+ *
+ * @param	convar		ConVar Handle.
+ * @param	flags		Flags to add.
+ */
+stock void Convar_AddFlags(ConVar convar, int flags)
+{
+	int newFlags = convar.Flags;
+	newFlags |= flags;
+	convar.Flags = newFlags;
+}
+
+/**
+ * Removes one ore more flags from a ConVar.
+ *
+ * @param	convar		ConVar Handle.
+ * @param	flags		Flags to remove
+ * @noreturn
+ */
+stock void Convar_RemoveFlags(ConVar convar, int flags)
+{
+	int newFlags = convar.Flags;
+	newFlags &= ~flags;
+	convar.Flags = newFlags;
+}
+
+/**
+ * Checks if a String is a valid ConVar or
+ * Console Command name.
+ *
+ * @param	name		String Name.
+ * @return				True if the name specified is a valid ConVar or console command name, false otherwise.
+ */
+stock bool Convar_IsValidName(const char[] name)
+{
+	if (name[0] == '\0') {
+		return false;
+	}
+
+	int n=0;
+	while (name[n] != '\0') {
+
+		if (!IsValidConVarChar(name[n])) {
+			return false;
+		}
+
+		n++;
+	}
+
+	return true;
+}

scripting/include/smlib/crypt.inc

@@ -0,0 +1,625 @@
+#if defined _smlib_crypt_included
+	#endinput
+#endif
+#define _smlib_crypt_included
+
+#include <sourcemod>
+
+/**********************************************************************************
+ *
+ * Base64 Encoding/Decoding Functions
+ * All Credits to to SirLamer & ScriptCoderPro
+ * Taken from http://forums.alliedmods.net/showthread.php?t=101764
+ *
+ ***********************************************************************************/
+
+// The Base64 encoding table
+static const char base64_sTable[] =
+  // 0000000000111111111122222222223333333333444444444455555555556666
+  // 0123456789012345678901234567890123456789012345678901234567890123
+    "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/";
+
+// The Base64 decoding table
+static const int base64_decodeTable[] = {
+//  0   1   2   3   4   5   6   7   8   9
+    0,  0,  0,  0,  0,  0,  0,  0,  0,  0,   //   0 -   9
+    0,  0,  0,  0,  0,  0,  0,  0,  0,  0,   //  10 -  19
+    0,  0,  0,  0,  0,  0,  0,  0,  0,  0,   //  20 -  29
+    0,  0,  0,  0,  0,  0,  0,  0,  0,  0,   //  30 -  39
+    0,  0,  0,  62, 0,  0,  0,  63, 52, 53,  //  40 -  49
+    54, 55, 56, 57, 58, 59, 60, 61, 0,  0,   //  50 -  59
+    0,  0,  0,  0,  0,  0,  1,  2,  3,  4,   //  60 -  69
+    5,  6,  7,  8,  9,  10, 11, 12, 13, 14,  //  70 -  79
+    15, 16, 17, 18, 19, 20, 21, 22, 23, 24,  //  80 -  89
+    25, 0,  0,  0,  0,  0,  0,  26, 27, 28,  //  90 -  99
+    29, 30, 31, 32, 33, 34, 35, 36, 37, 38,  // 100 - 109
+    39, 40, 41, 42, 43, 44, 45, 46, 47, 48,  // 110 - 119
+    49, 50, 51, 0,  0,  0,  0,  0,  0,  0,   // 120 - 129
+    0,  0,  0,  0,  0,  0,  0,  0,  0,  0,   // 130 - 139
+    0,  0,  0,  0,  0,  0,  0,  0,  0,  0,   // 140 - 149
+    0,  0,  0,  0,  0,  0,  0,  0,  0,  0,   // 150 - 159
+    0,  0,  0,  0,  0,  0,  0,  0,  0,  0,   // 160 - 169
+    0,  0,  0,  0,  0,  0,  0,  0,  0,  0,   // 170 - 179
+    0,  0,  0,  0,  0,  0,  0,  0,  0,  0,   // 180 - 189
+    0,  0,  0,  0,  0,  0,  0,  0,  0,  0,   // 190 - 199
+    0,  0,  0,  0,  0,  0,  0,  0,  0,  0,   // 200 - 209
+    0,  0,  0,  0,  0,  0,  0,  0,  0,  0,   // 210 - 219
+    0,  0,  0,  0,  0,  0,  0,  0,  0,  0,   // 220 - 229
+    0,  0,  0,  0,  0,  0,  0,  0,  0,  0,   // 230 - 239
+    0,  0,  0,  0,  0,  0,  0,  0,  0,  0,   // 240 - 249
+    0,  0,  0,  0,  0,  0                    // 250 - 256
+};
+
+/*
+ * For some reason the standard demands a string in 24-bit (3 character) intervals.
+ * This fill character is used to identify unused bytes at the end of the string.
+ */
+static const char base64_cFillChar			= '=';
+
+// The conversion characters between the standard and URL-compliance Base64 protocols
+static const char base64_mime_chars[]	= "+/=";
+static const char base64_url_chars[]	= "-_.";
+
+/*
+ * Encodes a string or binary data into Base64
+ *
+ * @param sString		The input string or binary data to be encoded.
+ * @param sResult		The storage buffer for the Base64-encoded result.
+ * @param len			The maximum length of the storage buffer, in characters/bytes.
+ * @param sourcelen 	(optional): The number of characters or length in bytes to be read from the input source.
+ *						This is not needed for a text string, but is important for binary data since there is no end-of-line character.
+ * @return				The length of the written Base64 string, in bytes.
+ */
+stock int Crypt_Base64Encode(const char[] sString, char[] sResult, int len, int sourcelen=0)
+{
+	int nLength;	// The string length to be read from the input
+	int resPos;		// The string position in the result buffer
+
+	// If the read length was specified, use it; otherwise, pull the string length from the input.
+	if (sourcelen > 0) {
+		nLength = sourcelen;
+	}
+	else {
+		nLength = strlen(sString);
+	}
+
+	// Loop through and generate the Base64 encoded string
+	// NOTE: This performs the standard encoding process.  Do not manipulate the logic within this loop.
+	for (int nPos = 0; nPos < nLength; nPos++) {
+		int cCode;
+
+		cCode = (sString[nPos] >> 2) & 0x3f;
+
+		resPos += FormatEx(sResult[resPos], len - resPos, "%c", base64_sTable[cCode]);
+
+		cCode = (sString[nPos] << 4) & 0x3f;
+		if (++nPos < nLength) {
+			cCode |= (sString[nPos] >> 4) & 0x0f;
+		}
+		resPos += FormatEx(sResult[resPos], len - resPos, "%c", base64_sTable[cCode]);
+
+		if ( nPos < nLength ) {
+			cCode = (sString[nPos] << 2) & 0x3f;
+			if (++nPos < nLength) {
+				cCode |= (sString[nPos] >> 6) & 0x03;
+			}
+
+			resPos += FormatEx(sResult[resPos], len - resPos, "%c", base64_sTable[cCode]);
+		}
+		else {
+			nPos++;
+			resPos += FormatEx(sResult[resPos], len - resPos, "%c", base64_cFillChar);
+		}
+
+		if (nPos < nLength) {
+			cCode = sString[nPos] & 0x3f;
+			resPos += FormatEx(sResult[resPos], len - resPos, "%c", base64_sTable[cCode]);
+		}
+		else {
+			resPos += FormatEx(sResult[resPos], len - resPos, "%c", base64_cFillChar);
+		}
+	}
+
+	return resPos;
+}
+
+
+/*
+ * Decodes a Base64 string.
+ *
+ * @param sString		The input string in compliant Base64 format to be decoded.
+ * @param sResult		The storage buffer for the decoded text strihg or binary data.
+ * @param len			The maximum length of the storage buffer, in characters/bytes.
+ * @return				The length of the decoded data, in bytes.
+ */
+stock int Crypt_Base64Decode(const char[] sString, char[] sResult, int len)
+{
+	int nLength = strlen(sString);	// The string length to be read from the input
+	int resPos;						// The string position in the result buffer
+
+	// Loop through and generate the Base64 encoded string
+	// NOTE: This performs the standard encoding process.  Do not manipulate the logic within this loop.
+	for (int nPos = 0; nPos < nLength; nPos++) {
+
+		int c, c1;
+
+		c	= base64_decodeTable[sString[nPos++]];
+		c1	= base64_decodeTable[sString[nPos]];
+
+		c = (c << 2) | ((c1 >> 4) & 0x3);
+
+		resPos += FormatEx(sResult[resPos], len - resPos, "%c", c);
+
+		if (++nPos < nLength) {
+
+			c = sString[nPos];
+
+			if (c == base64_cFillChar)
+				break;
+
+			c = base64_decodeTable[sString[nPos]];
+			c1 = ((c1 << 4) & 0xf0) | ((c >> 2) & 0xf);
+
+			resPos += FormatEx(sResult[resPos], len - resPos, "%c", c1);
+		}
+
+		if (++nPos < nLength) {
+
+			c1 = sString[nPos];
+
+			if (c1 == base64_cFillChar)
+				break;
+
+			c1 = base64_decodeTable[sString[nPos]];
+			c = ((c << 6) & 0xc0) | c1;
+
+			resPos += FormatEx(sResult[resPos], len - resPos, "%c", c);
+		}
+	}
+
+	return resPos;
+}
+
+
+/*
+ * Converts a standards-compliant Base64 string to the commonly accepted URL-compliant alternative.
+ * Note: The result will be the same length as the input string as long as the output buffer is large enough.
+ *
+ * @param sString		The standards-compliant Base64 input string to converted.
+ * @param sResult		The storage buffer for the URL-compliant result.
+ * @param len			The maximum length of the storage buffer in characters/bytes.
+ * @return				Number of cells written.
+ */
+stock int Crypt_Base64MimeToUrl(const char[] sString, char[] sResult, int len)
+{
+	int chars_len = sizeof(base64_mime_chars);	// Length of the two standards vs. URL character lists
+	int nLength;								// The string length to be read from the input
+	int temp_char;								// Buffer character
+
+	nLength = strlen(sString);
+
+	char[] sTemp = new char[nLength+1]; // Buffer string
+
+	// Loop through string
+	for (int i = 0; i < nLength; i++) {
+		temp_char = sString[i];
+
+		for (int j = 0; j < chars_len; j++) {
+
+			if(temp_char == base64_mime_chars[j]) {
+				temp_char = base64_url_chars[j];
+				break;
+			}
+		}
+
+		sTemp[i] = temp_char;
+	}
+
+	sTemp[nLength] = '\0';
+
+	return strcopy(sResult, len, sTemp);
+}
+
+/*
+ * Base64UrlToMime(String:sResult[], len, const String:sString[], sourcelen)
+ * Converts a URL-compliant Base64 string to the standards-compliant version.
+ * Note: The result will be the same length as the input string as long as the output buffer is large enough.
+ *
+ * @param sString		The URL-compliant Base64 input string to converted.
+ * @param sResult		The storage buffer for the standards-compliant result.
+ * @param len			The maximum length of the storage buffer in characters/bytes.
+ * @return				Number of cells written.
+ */
+stock int Crypt_Base64UrlToMime(const char[] sString, char[] sResult, int len)
+{
+	int chars_len = sizeof(base64_mime_chars);	// Length of the two standards vs. URL character lists
+	int nLength;								// The string length to be read from the input
+	int temp_char;								// Buffer character
+
+	nLength = strlen(sString);
+
+	char[] sTemp = new char[nLength+1]; // Buffer string
+
+	// Loop through string
+	for (int i = 0; i < nLength; i++) {
+		temp_char = sString[i];
+		for (int j = 0; j < chars_len; j++) {
+			if (temp_char == base64_url_chars[j]) {
+				temp_char = base64_mime_chars[j];
+				break;
+			}
+		}
+
+		sTemp[i] = temp_char;
+	}
+
+	sTemp[nLength] = '\0';
+
+	return strcopy(sResult, len, sTemp);
+}
+
+/**********************************************************************************
+ *
+ * MD5 Encoding Functions
+ * All Credits go to sslice
+ * RSA Data Security, Inc. MD5 Message Digest Algorithm
+ * Taken from http://forums.alliedmods.net/showthread.php?t=67683
+ *
+ ***********************************************************************************/
+
+/*
+ * Calculate the md5 hash of a string.
+ *
+ * @param str			Input String
+ * @param output		Output String Buffer
+ * @param maxlen		Size of the Output String Buffer
+ */
+stock void Crypt_MD5(const char[] str, char[] output, int maxlen)
+{
+	int x[2];
+	int buf[4];
+	int input[64];
+	int i, ii;
+
+	int len = strlen(str);
+
+	// MD5Init
+	x[0] = x[1] = 0;
+	buf[0] = 0x67452301;
+	buf[1] = 0xefcdab89;
+	buf[2] = 0x98badcfe;
+	buf[3] = 0x10325476;
+
+	// MD5Update
+	int update[16];
+
+	update[14] = x[0];
+	update[15] = x[1];
+
+	int mdi = (x[0] >>> 3) & 0x3F;
+
+	if ((x[0] + (len << 3)) < x[0]) {
+		x[1] += 1;
+	}
+
+	x[0] += len << 3;
+	x[1] += len >>> 29;
+
+	int c = 0;
+	while (len--) {
+		input[mdi] = str[c];
+		mdi += 1;
+		c += 1;
+
+		if (mdi == 0x40) {
+
+			for (i = 0, ii = 0; i < 16; ++i, ii += 4)
+			{
+				update[i] = (input[ii + 3] << 24) | (input[ii + 2] << 16) | (input[ii + 1] << 8) | input[ii];
+			}
+
+			// Transform
+			MD5Transform(buf, update);
+
+			mdi = 0;
+		}
+	}
+
+	// MD5Final
+	int padding[64] = {
+		0x80, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,
+		0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,
+		0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,
+		0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,
+		0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,
+		0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,
+		0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,
+		0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00
+	};
+
+	int inx[16];
+	inx[14] = x[0];
+	inx[15] = x[1];
+
+	mdi = (x[0] >>> 3) & 0x3F;
+
+	len = (mdi < 56) ? (56 - mdi) : (120 - mdi);
+	update[14] = x[0];
+	update[15] = x[1];
+
+	mdi = (x[0] >>> 3) & 0x3F;
+
+	if ((x[0] + (len << 3)) < x[0]) {
+		x[1] += 1;
+	}
+
+	x[0] += len << 3;
+	x[1] += len >>> 29;
+
+	c = 0;
+	while (len--) {
+		input[mdi] = padding[c];
+		mdi += 1;
+		c += 1;
+
+		if (mdi == 0x40) {
+
+			for (i = 0, ii = 0; i < 16; ++i, ii += 4) {
+				update[i] = (input[ii + 3] << 24) | (input[ii + 2] << 16) | (input[ii + 1] << 8) | input[ii];
+			}
+
+			// Transform
+			MD5Transform(buf, update);
+
+			mdi = 0;
+		}
+	}
+
+	for (i = 0, ii = 0; i < 14; ++i, ii += 4) {
+		inx[i] = (input[ii + 3] << 24) | (input[ii + 2] << 16) | (input[ii + 1] << 8) | input[ii];
+	}
+
+	MD5Transform(buf, inx);
+
+	int digest[16];
+	for (i = 0, ii = 0; i < 4; ++i, ii += 4) {
+		digest[ii] = (buf[i]) & 0xFF;
+		digest[ii + 1] = (buf[i] >>> 8) & 0xFF;
+		digest[ii + 2] = (buf[i] >>> 16) & 0xFF;
+		digest[ii + 3] = (buf[i] >>> 24) & 0xFF;
+	}
+
+	FormatEx(output, maxlen, "%02x%02x%02x%02x%02x%02x%02x%02x%02x%02x%02x%02x%02x%02x%02x%02x",
+		digest[0], digest[1], digest[2], digest[3], digest[4], digest[5], digest[6], digest[7],
+		digest[8], digest[9], digest[10], digest[11], digest[12], digest[13], digest[14], digest[15]);
+}
+
+static stock void MD5Transform_FF(int &a, int &b, int &c, int &d, int x, int s, int ac)
+{
+	a += (((b) & (c)) | ((~b) & (d))) + x + ac;
+	a = (((a) << (s)) | ((a) >>> (32-(s))));
+	a += b;
+}
+
+static stock void MD5Transform_GG(int &a, int &b, int &c, int &d, int x, int s, int ac)
+{
+	a += (((b) & (d)) | ((c) & (~d))) + x + ac;
+	a = (((a) << (s)) | ((a) >>> (32-(s))));
+	a += b;
+}
+
+static stock void MD5Transform_HH(int &a, int &b, int &c, int &d, int x, int s, int ac)
+	{
+	a += ((b) ^ (c) ^ (d)) + x + ac;
+	a = (((a) << (s)) | ((a) >>> (32-(s))));
+	a += b;
+}
+
+static stock void MD5Transform_II(int &a, int &b, int &c, int &d, int x, int s, int ac)
+{
+	a += ((c) ^ ((b) | (~d))) + x + ac;
+	a = (((a) << (s)) | ((a) >>> (32-(s))));
+	a += b;
+}
+
+static stock void MD5Transform(int[] buf, int[] input){
+	int a = buf[0];
+	int b = buf[1];
+	int c = buf[2];
+	int d = buf[3];
+
+	MD5Transform_FF(a, b, c, d, input[0], 7, 0xd76aa478);
+	MD5Transform_FF(d, a, b, c, input[1], 12, 0xe8c7b756);
+	MD5Transform_FF(c, d, a, b, input[2], 17, 0x242070db);
+	MD5Transform_FF(b, c, d, a, input[3], 22, 0xc1bdceee);
+	MD5Transform_FF(a, b, c, d, input[4], 7, 0xf57c0faf);
+	MD5Transform_FF(d, a, b, c, input[5], 12, 0x4787c62a);
+	MD5Transform_FF(c, d, a, b, input[6], 17, 0xa8304613);
+	MD5Transform_FF(b, c, d, a, input[7], 22, 0xfd469501);
+	MD5Transform_FF(a, b, c, d, input[8], 7, 0x698098d8);
+	MD5Transform_FF(d, a, b, c, input[9], 12, 0x8b44f7af);
+	MD5Transform_FF(c, d, a, b, input[10], 17, 0xffff5bb1);
+	MD5Transform_FF(b, c, d, a, input[11], 22, 0x895cd7be);
+	MD5Transform_FF(a, b, c, d, input[12], 7, 0x6b901122);
+	MD5Transform_FF(d, a, b, c, input[13], 12, 0xfd987193);
+	MD5Transform_FF(c, d, a, b, input[14], 17, 0xa679438e);
+	MD5Transform_FF(b, c, d, a, input[15], 22, 0x49b40821);
+
+	MD5Transform_GG(a, b, c, d, input[1], 5, 0xf61e2562);
+	MD5Transform_GG(d, a, b, c, input[6], 9, 0xc040b340);
+	MD5Transform_GG(c, d, a, b, input[11], 14, 0x265e5a51);
+	MD5Transform_GG(b, c, d, a, input[0], 20, 0xe9b6c7aa);
+	MD5Transform_GG(a, b, c, d, input[5], 5, 0xd62f105d);
+	MD5Transform_GG(d, a, b, c, input[10], 9, 0x02441453);
+	MD5Transform_GG(c, d, a, b, input[15], 14, 0xd8a1e681);
+	MD5Transform_GG(b, c, d, a, input[4], 20, 0xe7d3fbc8);
+	MD5Transform_GG(a, b, c, d, input[9], 5, 0x21e1cde6);
+	MD5Transform_GG(d, a, b, c, input[14], 9, 0xc33707d6);
+	MD5Transform_GG(c, d, a, b, input[3], 14, 0xf4d50d87);
+	MD5Transform_GG(b, c, d, a, input[8], 20, 0x455a14ed);
+	MD5Transform_GG(a, b, c, d, input[13], 5, 0xa9e3e905);
+	MD5Transform_GG(d, a, b, c, input[2], 9, 0xfcefa3f8);
+	MD5Transform_GG(c, d, a, b, input[7], 14, 0x676f02d9);
+	MD5Transform_GG(b, c, d, a, input[12], 20, 0x8d2a4c8a);
+
+	MD5Transform_HH(a, b, c, d, input[5], 4, 0xfffa3942);
+	MD5Transform_HH(d, a, b, c, input[8], 11, 0x8771f681);
+	MD5Transform_HH(c, d, a, b, input[11], 16, 0x6d9d6122);
+	MD5Transform_HH(b, c, d, a, input[14], 23, 0xfde5380c);
+	MD5Transform_HH(a, b, c, d, input[1], 4, 0xa4beea44);
+	MD5Transform_HH(d, a, b, c, input[4], 11, 0x4bdecfa9);
+	MD5Transform_HH(c, d, a, b, input[7], 16, 0xf6bb4b60);
+	MD5Transform_HH(b, c, d, a, input[10], 23, 0xbebfbc70);
+	MD5Transform_HH(a, b, c, d, input[13], 4, 0x289b7ec6);
+	MD5Transform_HH(d, a, b, c, input[0], 11, 0xeaa127fa);
+	MD5Transform_HH(c, d, a, b, input[3], 16, 0xd4ef3085);
+	MD5Transform_HH(b, c, d, a, input[6], 23, 0x04881d05);
+	MD5Transform_HH(a, b, c, d, input[9], 4, 0xd9d4d039);
+	MD5Transform_HH(d, a, b, c, input[12], 11, 0xe6db99e5);
+	MD5Transform_HH(c, d, a, b, input[15], 16, 0x1fa27cf8);
+	MD5Transform_HH(b, c, d, a, input[2], 23, 0xc4ac5665);
+
+	MD5Transform_II(a, b, c, d, input[0], 6, 0xf4292244);
+	MD5Transform_II(d, a, b, c, input[7], 10, 0x432aff97);
+	MD5Transform_II(c, d, a, b, input[14], 15, 0xab9423a7);
+	MD5Transform_II(b, c, d, a, input[5], 21, 0xfc93a039);
+	MD5Transform_II(a, b, c, d, input[12], 6, 0x655b59c3);
+	MD5Transform_II(d, a, b, c, input[3], 10, 0x8f0ccc92);
+	MD5Transform_II(c, d, a, b, input[10], 15, 0xffeff47d);
+	MD5Transform_II(b, c, d, a, input[1], 21, 0x85845dd1);
+	MD5Transform_II(a, b, c, d, input[8], 6, 0x6fa87e4f);
+	MD5Transform_II(d, a, b, c, input[15], 10, 0xfe2ce6e0);
+	MD5Transform_II(c, d, a, b, input[6], 15, 0xa3014314);
+	MD5Transform_II(b, c, d, a, input[13], 21, 0x4e0811a1);
+	MD5Transform_II(a, b, c, d, input[4], 6, 0xf7537e82);
+	MD5Transform_II(d, a, b, c, input[11], 10, 0xbd3af235);
+	MD5Transform_II(c, d, a, b, input[2], 15, 0x2ad7d2bb);
+	MD5Transform_II(b, c, d, a, input[9], 21, 0xeb86d391);
+
+	buf[0] += a;
+	buf[1] += b;
+	buf[2] += c;
+	buf[3] += d;
+}
+
+/**********************************************************************************
+ *
+ * RC4 Encoding Functions
+ * All Credits go to SirLamer and Raydan
+ * Taken from http://forums.alliedmods.net/showthread.php?t=101834
+ *
+ ***********************************************************************************/
+
+/*
+ * Encrypts a text string using RC4.
+ * Note: This function is NOT binary safe.
+ * Use Crypt_RC4EncodeBinary to encode binary data.
+ *
+ * @param input			The source data to be encrypted.
+ * @param pwd			The password/key used to encode and decode the data.
+ * @param output		The encoded result.
+ * @param maxlen		The maximum length of the output buffer.
+ */
+stock void Crypt_RC4Encode(const char[] input, const char[] pwd, char[] output, int maxlen)
+{
+	int pwd_len,str_len,i,j,a,k;
+	int key[256];
+	int box[256];
+	int tmp;
+
+	pwd_len = strlen(pwd);
+	str_len = strlen(input);
+
+	if (pwd_len > 0 && str_len > 0) {
+
+		for (i=0; i < 256; i++) {
+			key[i] = pwd[i%pwd_len];
+			box[i]=i;
+		}
+
+		i=0; j=0;
+
+		for (; i < 256; i++) {
+			j = (j + box[i] + key[i]) % 256;
+			tmp = box[i];
+			box[i] = box[j];
+			box[j] = tmp;
+		}
+
+		i=0; j=0; a=0;
+
+		for (; i < str_len; i++)	{
+			a = (a + 1) % 256;
+			j = (j + box[a]) % 256;
+			tmp = box[a];
+			box[a] = box[j];
+			box[j] = tmp;
+			k = box[((box[a] + box[j]) % 256)];
+			FormatEx(output[2*i], maxlen-2*i, "%02x", input[i] ^ k);
+		}
+	}
+}
+
+/*
+ * Encrypts binary data using RC4.
+ *
+ * @param input			The source data to be encrypted.
+ * @param str_len		The length of the source data.
+ * @param pwd			The password/key used to encode and decode the data.
+ * @param output		The encoded result.
+ * @param maxlen		The maximum length of the output buffer.
+ */
+stock int Crypt_RC4EncodeBinary(const char[] input, int str_len, const char[] pwd, char[] output, int maxlen)
+{
+	int pwd_len,i,j,a,k;
+	int key[256];
+	int box[256];
+	int tmp;
+
+	pwd_len = strlen(pwd);
+
+	if (pwd_len > 0 && str_len > 0) {
+
+		for(i=0;i<256;i++) {
+			key[i] = pwd[i%pwd_len];
+			box[i]=i;
+		}
+
+		i=0; j=0;
+
+		for (; i < 256; i++) {
+			j = (j + box[i] + key[i]) % 256;
+			tmp = box[i];
+			box[i] = box[j];
+			box[j] = tmp;
+		}
+
+		i=0; j=0; a=0;
+
+		if (str_len+1 > maxlen) {
+			str_len = maxlen - 1;
+		}
+
+		for(; i < str_len; i++)	{
+			a = (a + 1) % 256;
+			j = (j + box[a]) % 256;
+			tmp = box[a];
+			box[a] = box[j];
+			box[j] = tmp;
+			k = box[((box[a] + box[j]) % 256)];
+			FormatEx(output[i], maxlen-i, "%c", input[i] ^ k);
+		}
+
+		/*
+		 * i = number of written bits (remember increment occurs at end of for loop, and THEN it fails the loop condition)
+		 * Since we're working with binary data, the calling function should not depend on the escape
+		 * character, but putting it here prevents crashes in case someone tries to read the data like a string
+		 */
+		output[i] = '\0';
+
+		return i;
+	}
+	else {
+		return -1;
+	}
+}

scripting/include/smlib/debug.inc

@@ -0,0 +1,28 @@
+#if defined _smlib_debug_included
+	#endinput
+#endif
+#define _smlib_debug_included
+
+#include <sourcemod>
+
+/**
+ * Prints the values of a static Float-Array to the server console.
+ *
+ * @param array		Static Float-Array.
+ * @param size		Size of the Array.
+ */
+stock void Debug_FloatArray(const float[] array, int size=3)
+{
+	char output[64] = "";
+
+	for (int i=0; i < size; ++i) {
+
+		if (i > 0 && i < size) {
+			StrCat(output, sizeof(output), ", ");
+		}
+
+		Format(output, sizeof(output), "%s%f", output, array[i]);
+	}
+
+	PrintToServer("[DEBUG] Vector[%d] = { %s }", size, output);
+}

scripting/include/smlib/dynarrays.inc

@@ -0,0 +1,24 @@
+#if defined _smlib_dynarray_included
+	#endinput
+#endif
+#define _smlib_dynarray_included
+
+#include <sourcemod>
+
+/**
+ * Retrieves a cell value from an array.
+ * This is a wrapper around the Sourcemod Function GetArrayCell,
+ * but it casts the result as bool
+ *
+ * @param array			Array Handle.
+ * @param index			Index in the array.
+ * @param block			Optionally specify which block to read from
+ *						(useful if the blocksize > 0).
+ * @param asChar		Optionally read as a byte instead of a cell.
+ * @return				Value read.
+ * @error				Invalid Handle, invalid index, or invalid block.
+ */
+stock bool DynArray_GetBool(ArrayList array, int index, int block=0, bool asChar=false)
+{
+	return array.Get(index, block, asChar) != 0;
+}

scripting/include/smlib/edicts.inc

@@ -0,0 +1,127 @@
+#if defined _smlib_edicts_included
+	#endinput
+#endif
+#define _smlib_edicts_included
+
+#include <sourcemod>
+#include <smlib/entities>
+
+/*
+ * Finds an edict by it's name
+ * It only finds the first occurence.
+ *
+ * @param name			Name of the entity you want so search.
+ * @return				Edict Index or INVALID_ENT_REFERENCE if no entity was found.
+ */
+stock int Edict_FindByName(const char[] name)
+{
+	int maxEntities = GetMaxEntities();
+	for (int edict=0; edict < maxEntities; edict++) {
+
+		if (!IsValidEdict(edict)) {
+			continue;
+		}
+
+		if (Entity_NameMatches(edict, name)) {
+			return edict;
+		}
+	}
+
+	return INVALID_ENT_REFERENCE;
+}
+
+/*
+ * Finds an edict by its HammerID.
+ * The newer version of Valve's Hammer editor
+ * sets a unique ID for each entity in a map.
+ * It only finds the first occurence.
+ *
+ * @param hammerId		Hammer editor ID
+ * @return				Edict Index or INVALID_ENT_REFERENCE if no entity was found.
+ */
+stock int Edict_FindByHammerId(int hammerId)
+{
+	int maxEntities = GetMaxEntities();
+	for (int edict=0; edict < maxEntities; edict++) {
+
+		if (!IsValidEdict(edict)) {
+			continue;
+		}
+
+		if (Entity_GetHammerId(edict) == hammerId) {
+			return edict;
+		}
+	}
+
+	return INVALID_ENT_REFERENCE;
+}
+
+/**
+ * Searches for the closest edict in relation to the given origin
+ *
+ * @param vecOrigin_center	3 dimensional origin array
+ * @param clientsOnly		True if you only want to search for clients
+ * @param ignoreEntity		Ignore this entity
+ * @return					Edict Index or INVALID_ENT_REFERENCE if no entity was found.
+ */
+stock int Edict_GetClosest(float vecOrigin_center[3], bool clientsOnly=false, int ignoreEntity=-1)
+{
+	float vecOrigin_edict[3];
+	float smallestDistance = 0.0;
+	int closestEdict = INVALID_ENT_REFERENCE;
+
+	int maxEntities;
+
+	if (clientsOnly) {
+		maxEntities = MaxClients;
+	}
+	else {
+		maxEntities = GetMaxEntities();
+	}
+
+	for (int edict=1; edict <= maxEntities; edict++) {
+
+		if (!IsValidEdict(edict)) {
+			continue;
+		}
+
+		if (ignoreEntity >= 0 && edict == ignoreEntity) {
+			continue;
+		}
+
+		if (GetEntSendPropOffs(edict, "m_vecOrigin") == -1) {
+			continue;
+		}
+
+		Entity_GetAbsOrigin(edict, vecOrigin_edict);
+
+		float edict_distance = GetVectorDistance(vecOrigin_center, vecOrigin_edict, true);
+
+		if (edict_distance < smallestDistance || smallestDistance == 0.0) {
+			smallestDistance = edict_distance;
+			closestEdict = edict;
+		}
+	}
+
+	return closestEdict;
+}
+
+/**
+ * Searches for the closest edict in relation to the given edict.
+ *
+ * @param edict				Edict index
+ * @param clientsOnly		True if you only want to search for clients
+ * @return					The closest edict or INVALID_ENT_REFERENCE
+ */
+stock int Edict_GetClosestToEdict(int edict, bool clientsOnly=false)
+{
+	float vecOrigin[3];
+
+	if (!HasEntProp(edict, Prop_Send, "m_vecOrigin")) {
+		return INVALID_ENT_REFERENCE;
+	}
+
+	Entity_GetAbsOrigin(edict, vecOrigin);
+
+	return Edict_GetClosest(vecOrigin, clientsOnly, edict);
+}

scripting/include/smlib/effects.inc

@@ -0,0 +1,722 @@
+#if defined _smlib_effects_included
+	#endinput
+#endif
+#define _smlib_effects_included
+
+#include <sourcemod>
+#include <sdktools_entinput>
+#include <sdktools_tempents>
+#include <sdktools_tempents_stocks>
+#include <smlib/clients>
+#include <smlib/effects>
+#include <smlib/entities>
+#include <smlib/math>
+
+
+
+// Entity Dissolve types
+enum DissolveType
+{
+	DISSOLVE_NORMAL = 0,
+	DISSOLVE_ELECTRICAL,
+	DISSOLVE_ELECTRICAL_LIGHT,
+	DISSOLVE_CORE
+};
+
+/**
+ * Dissolves a player
+ *
+ * @param client		Client Index.
+ * @param dissolveType	Dissolve Type, use the DissolveType enum.
+ * @param magnitude		How strongly to push away from the center.
+ * @return				True on success, otherwise false.
+ */
+stock bool Effect_DissolveEntity(int entity, DissolveType dissolveType=DISSOLVE_NORMAL, int magnitude=1)
+{
+	int env_entity_dissolver = CreateEntityByName("env_entity_dissolver");
+
+	if (env_entity_dissolver == -1) {
+		return false;
+	}
+
+	Entity_PointAtTarget(env_entity_dissolver, entity);
+	SetEntProp(env_entity_dissolver, Prop_Send, "m_nDissolveType", dissolveType);
+	SetEntProp(env_entity_dissolver, Prop_Send, "m_nMagnitude", magnitude);
+	AcceptEntityInput(env_entity_dissolver,	"Dissolve");
+	Entity_Kill(env_entity_dissolver);
+
+	return true;
+}
+
+/**
+ * Dissolves a player's Ragdoll
+ *
+ * @param client		Client Index.
+ * @param dissolveType	Dissolve Type, use the DissolveType enum.
+ * @return				True on success, otherwise false.
+ */
+stock bool Effect_DissolvePlayerRagDoll(int client, DissolveType dissolveType=DISSOLVE_NORMAL)
+{
+	int m_hRagdoll = GetEntPropEnt(client, Prop_Send, "m_hRagdoll");
+
+	if (m_hRagdoll == -1) {
+		return false;
+	}
+
+	return Effect_DissolveEntity(m_hRagdoll, dissolveType);
+}
+
+typedef EffectCallback = function void(int entity, any data);
+
+/**
+ * Fades an entity in our out.
+ * You can specifiy a callback function which will get called
+ * when the fade is finished.
+ * Important: The callback will be called if it is passed,
+ * no matter if the entity is still valid or not. That means you
+ * have to check if the entity is valid yourself.
+ *
+ * @param entity		Entity Index.
+ * @param fadeOut		Optional: Fade the entity out (true) or in (false).
+ * @param kill			Optional: If to kill the entity when the fade is finished.
+ * @param fast			Optional: Fade the entity fast (~0.7 secs) or slow (~3 secs)
+ * @param callback		Optional: You can specify a callback Function that will get called when the fade is finished.
+ * @param data			Optional: You can pass any data to the callback.
+ */
+stock void Effect_Fade(int entity, bool fadeOut=true, bool kill=false, bool fast=true, EffectCallback callback=INVALID_FUNCTION, any data=0)
+{
+	float timerTime = 0.0;
+
+	if (fast) {
+		timerTime = 0.6;
+
+		if (fadeOut) {
+			SetEntityRenderFx(entity, RENDERFX_FADE_FAST);
+		}
+		else {
+			SetEntityRenderFx(entity, RENDERFX_SOLID_FAST);
+		}
+	}
+	else {
+		timerTime = 3.0;
+
+		if (fadeOut) {
+			SetEntityRenderFx(entity, RENDERFX_FADE_SLOW);
+		}
+		else {
+			SetEntityRenderFx(entity, RENDERFX_SOLID_SLOW);
+		}
+	}
+
+	ChangeEdictState(entity, GetEntSendPropOffs(entity, "m_nRenderFX", true));
+
+	if (kill || callback != INVALID_FUNCTION) {
+		DataPack dataPack = null;
+		CreateDataTimer(timerTime, _smlib_Timer_Effect_Fade, dataPack, TIMER_FLAG_NO_MAPCHANGE | TIMER_DATA_HNDL_CLOSE);
+
+		WritePackCell(dataPack, EntIndexToEntRef(entity));
+		WritePackCell(dataPack, kill);
+		WritePackFunction(dataPack, callback);
+		WritePackCell(dataPack, data);
+		ResetPack(dataPack);
+	}
+}
+
+/**
+ * Fades the entity in.
+ *  A wrapper function around Effect_Fade().
+ *
+ * @param entity		Entity Index.
+ * @param fast			Optional: Fade the entity fast (~0.7 secs) or slow (~3 secs)
+ * @param callback		Optional: You can specify a callback Function that will get called when the fade is finished.
+ * @param data			Optional: You can pass any data to the callback.
+ */
+stock void Effect_FadeIn(int entity, bool fast=true, EffectCallback callback=INVALID_FUNCTION, any data=0)
+{
+	Effect_Fade(entity, false, false, fast, callback, data);
+}
+
+/**
+ * Fades the entity out.
+ * A wrapper function around Effect_Fade().
+ *
+ * @param entity		Entity Index.
+ * @param fadeOut		Optional: Fade the entity out (true) or in (false).
+ * @param kill			Optional: If to kill the entity when the fade is finished.
+ * @param fast			Optional: Fade the entity fast (~0.7 secs) or slow (~3 secs)
+ * @param callback		Optional: You can specify a callback Function that will get called when the fade is finished.
+ * @param data			Optional: You can pass any data to the callback.
+ */
+stock void Effect_FadeOut(int entity, bool kill=false, bool fast=true, EffectCallback callback=INVALID_FUNCTION, any data=0)
+{
+	Effect_Fade(entity, true, kill, fast, callback, data);
+}
+
+public Action _smlib_Timer_Effect_Fade(Handle Timer, DataPack dataPack)
+{
+	int entity = ReadPackCell(dataPack);
+	int kill = ReadPackCell(dataPack);
+	Function callback = ReadPackFunction(dataPack);
+	any data = ReadPackCell(dataPack);
+
+	if (callback != INVALID_FUNCTION) {
+		Call_StartFunction(INVALID_HANDLE, callback);
+		Call_PushCell(entity);
+		Call_PushCell(data);
+		Call_Finish();
+	}
+
+	if (kill && IsValidEntity(entity)) {
+		Entity_Kill(entity);
+	}
+
+	return Plugin_Stop;
+}
+
+/**
+ * Sends a boxed beam effect to one player.
+ *
+ * Ported from eventscripts vecmath library.
+ *
+ * @param client        The client to show the box to.
+ * @param bottomCorner	One bottom corner of the box.
+ * @param upperCorner	One upper corner of the box.
+ * @param modelIndex	Precached model index.
+ * @param haloIndex		Precached model index.
+ * @param startFrame	Initital frame to render.
+ * @param frameRate		Beam frame rate.
+ * @param life			Time duration of the beam.
+ * @param width			Initial beam width.
+ * @param endWidth		Final beam width.
+ * @param fadeLength	Beam fade time duration.
+ * @param amplitude		Beam amplitude.
+ * @param color			Color array (r, g, b, a).
+ * @param speed			Speed of the beam.
+ */
+stock void Effect_DrawBeamBoxToClient(
+	int client,
+	const float bottomCorner[3],
+	const float upperCorner[3],
+	int modelIndex,
+	int haloIndex,
+	int startFrame=0,
+	int frameRate=30,
+	float life=5.0,
+	float width=5.0,
+	float endWidth=5.0,
+	int fadeLength=2,
+	float amplitude=1.0,
+	const int color[4]={ 255, 0, 0, 255 },
+	int speed=0
+) {
+    int clients[1];
+    clients[0] = client;
+    Effect_DrawBeamBox(clients, 1, bottomCorner, upperCorner, modelIndex, haloIndex, startFrame, frameRate, life, width, endWidth, fadeLength, amplitude, color, speed);
+}
+
+/**
+ * Sends a boxed beam effect to all players.
+ *
+ * Ported from eventscripts vecmath library.
+ *
+ * @param bottomCorner	One bottom corner of the box.
+ * @param upperCorner	One upper corner of the box.
+ * @param modelIndex	Precached model index.
+ * @param haloIndex		Precached model index.
+ * @param startFrame	Initital frame to render.
+ * @param frameRate		Beam frame rate.
+ * @param life			Time duration of the beam.
+ * @param width			Initial beam width.
+ * @param endWidth		Final beam width.
+ * @param fadeLength	Beam fade time duration.
+ * @param amplitude		Beam amplitude.
+ * @param color			Color array (r, g, b, a).
+ * @param speed			Speed of the beam.
+ */
+stock void Effect_DrawBeamBoxToAll(
+	const float bottomCorner[3],
+	const float upperCorner[3],
+	int modelIndex,
+	int haloIndex,
+	int startFrame=0,
+	int frameRate=30,
+	float life=5.0,
+	float width=5.0,
+	float endWidth=5.0,
+	int fadeLength=2,
+	float amplitude=1.0,
+	const int color[4]={ 255, 0, 0, 255 },
+	int speed=0
+)
+{
+	int[] clients = new int[MaxClients];
+	int numClients = Client_Get(clients, CLIENTFILTER_INGAME);
+
+	Effect_DrawBeamBox(clients, numClients, bottomCorner, upperCorner, modelIndex, haloIndex, startFrame, frameRate, life, width, endWidth, fadeLength, amplitude, color, speed);
+}
+
+/**
+ * Sends a boxed beam effect to a list of players.
+ *
+ * Ported from eventscripts vecmath library.
+ *
+ * @param clients       An array of clients to show the box to.
+ * @param numClients    Number of players in the array.
+ * @param bottomCorner	One bottom corner of the box.
+ * @param upperCorner	One upper corner of the box.
+ * @param modelIndex	Precached model index.
+ * @param haloIndex		Precached model index.
+ * @param startFrame	Initital frame to render.
+ * @param frameRate		Beam frame rate.
+ * @param life			Time duration of the beam.
+ * @param width			Initial beam width.
+ * @param endWidth		Final beam width.
+ * @param fadeLength	Beam fade time duration.
+ * @param amplitude		Beam amplitude.
+ * @param color			Color array (r, g, b, a).
+ * @param speed			Speed of the beam.
+ */
+stock void Effect_DrawBeamBox(
+	int[] clients,
+	int numClients,
+	const float bottomCorner[3],
+	const float upperCorner[3],
+	int modelIndex,
+	int haloIndex,
+	int startFrame=0,
+	int frameRate=30,
+	float life=5.0,
+	float width=5.0,
+	float endWidth=5.0,
+	int fadeLength=2,
+	float amplitude=1.0,
+	const int color[4]={ 255, 0, 0, 255 },
+	int speed=0
+) {
+	// Create the additional corners of the box
+	float corners[8][3];
+
+	for (int i=0; i < 4; i++) {
+		Array_Copy(bottomCorner,	corners[i],		3);
+		Array_Copy(upperCorner,		corners[i+4],	3);
+	}
+
+	corners[1][0] = upperCorner[0];
+	corners[2][0] = upperCorner[0];
+	corners[2][1] = upperCorner[1];
+	corners[3][1] = upperCorner[1];
+	corners[4][0] = bottomCorner[0];
+	corners[4][1] = bottomCorner[1];
+	corners[5][1] = bottomCorner[1];
+	corners[7][0] = bottomCorner[0];
+
+    // Draw all the edges
+
+	// Horizontal Lines
+	// Bottom
+	for (int i=0; i < 4; i++) {
+		int j = ( i == 3 ? 0 : i+1 );
+		TE_SetupBeamPoints(corners[i], corners[j], modelIndex, haloIndex, startFrame, frameRate, life, width, endWidth, fadeLength, amplitude, color, speed);
+		TE_Send(clients, numClients);
+	}
+
+	// Top
+	for (int i=4; i < 8; i++) {
+		int j = ( i == 7 ? 4 : i+1 );
+		TE_SetupBeamPoints(corners[i], corners[j], modelIndex, haloIndex, startFrame, frameRate, life, width, endWidth, fadeLength, amplitude, color, speed);
+		TE_Send(clients, numClients);
+	}
+
+	// All Vertical Lines
+	for (int i=0; i < 4; i++) {
+		TE_SetupBeamPoints(corners[i], corners[i+4], modelIndex, haloIndex, startFrame, frameRate, life, width, endWidth, fadeLength, amplitude, color, speed);
+		TE_Send(clients, numClients);
+	}
+}
+
+
+/**
+ * Sends a boxed beam effect to one player.
+ *
+ * Ported from eventscripts vecmath library.
+ *
+ * @param client        The client to show the box to.
+ * @param origin 		Origin/center of the box.
+ * @param mins			Min size Vector
+ * @param maxs			Max size Vector
+ * @param angles 		Angles used to rotate the box.
+ * @param modelIndex	Precached model index.
+ * @param haloIndex		Precached model index.
+ * @param startFrame	Initital frame to render.
+ * @param frameRate		Beam frame rate.
+ * @param life			Time duration of the beam.
+ * @param width			Initial beam width.
+ * @param endWidth		Final beam width.
+ * @param fadeLength	Beam fade time duration.
+ * @param amplitude		Beam amplitude.
+ * @param color			Color array (r, g, b, a).
+ * @param speed			Speed of the beam.
+ */
+stock void Effect_DrawBeamBoxRotatableToClient(
+	int client,
+	const float origin[3],
+	const float mins[3],
+	const float maxs[3],
+	const float angles[3],
+	int modelIndex,
+	int haloIndex,
+	int startFrame=0,
+	int frameRate=30,
+	float life=5.0,
+	float width=5.0,
+	float endWidth=5.0,
+	int fadeLength=2,
+	float amplitude=1.0,
+	const int color[4]={ 255, 0, 0, 255 },
+	int speed=0
+) {
+    int clients[1];
+    clients[0] = client;
+    Effect_DrawBeamBoxRotatable(clients, 1, origin, mins, maxs, angles, modelIndex, haloIndex, startFrame, frameRate, life, width, endWidth, fadeLength, amplitude, color, speed);
+}
+
+
+
+/**
+ * Sends a boxed beam effect to all players.
+ *
+ * Ported from eventscripts vecmath library.
+ *
+ * @param origin 		Origin/center of the box.
+ * @param mins			Min size Vector
+ * @param maxs			Max size Vector
+ * @param angles 		Angles used to rotate the box.
+ * @param modelIndex	Precached model index.
+ * @param haloIndex		Precached model index.
+ * @param startFrame	Initital frame to render.
+ * @param frameRate		Beam frame rate.
+ * @param life			Time duration of the beam.
+ * @param width			Initial beam width.
+ * @param endWidth		Final beam width.
+ * @param fadeLength	Beam fade time duration.
+ * @param amplitude		Beam amplitude.
+ * @param color			Color array (r, g, b, a).
+ * @param speed			Speed of the beam.
+ */
+stock void Effect_DrawBeamBoxRotatableToAll(
+	const float origin[3],
+	const float mins[3],
+	const float maxs[3],
+	const float angles[3],
+	int modelIndex,
+	int haloIndex,
+	int startFrame=0,
+	int frameRate=30,
+	float life=5.0,
+	float width=5.0,
+	float endWidth=5.0,
+	int fadeLength=2,
+	float amplitude=1.0,
+	const int color[4]={ 255, 0, 0, 255 },
+	int speed=0
+)
+{
+	int[] clients = new int[MaxClients];
+	int numClients = Client_Get(clients, CLIENTFILTER_INGAME);
+
+	Effect_DrawBeamBoxRotatable(clients, numClients, origin, mins, maxs, angles, modelIndex, haloIndex, startFrame, frameRate, life, width, endWidth, fadeLength, amplitude, color, speed);
+}
+
+/**
+ * Sends a boxed beam effect to a list of players.
+ *
+ * Ported from eventscripts vecmath library.
+ *
+ * @param clients       An array of clients to show the box to.
+ * @param numClients    Number of players in the array.
+ * @param origin 		Origin/center of the box.
+ * @param mins			Min size Vector
+ * @param maxs			Max size Vector
+ * @param angles 		Angles used to rotate the box.
+ * @param modelIndex	Precached model index.
+ * @param haloIndex		Precached model index.
+ * @param startFrame	Initital frame to render.
+ * @param frameRate		Beam frame rate.
+ * @param life			Time duration of the beam.
+ * @param width			Initial beam width.
+ * @param endWidth		Final beam width.
+ * @param fadeLength	Beam fade time duration.
+ * @param amplitude		Beam amplitude.
+ * @param color			Color array (r, g, b, a).
+ * @param speed			Speed of the beam.
+ */
+stock void Effect_DrawBeamBoxRotatable(
+	int[] clients,
+	int numClients,
+	const float origin[3],
+	const float mins[3],
+	const float maxs[3],
+	const float angles[3],
+	int modelIndex,
+	int haloIndex,
+	int startFrame=0,
+	int frameRate=30,
+	float life=5.0,
+	float width=5.0,
+	float endWidth=5.0,
+	int fadeLength=2,
+	float amplitude=1.0,
+	const int color[4]={ 255, 0, 0, 255 },
+	int speed=0
+) {
+	// Create the additional corners of the box
+	float corners[8][3];
+	Array_Copy(mins, corners[0], 3);
+	Math_MakeVector(maxs[0], mins[1], mins[2], corners[1]);
+	Math_MakeVector(maxs[0], maxs[1], mins[2], corners[2]);
+	Math_MakeVector(mins[0], maxs[1], mins[2], corners[3]);
+	Math_MakeVector(mins[0], mins[1], maxs[2], corners[4]);
+	Math_MakeVector(maxs[0], mins[1], maxs[2], corners[5]);
+	Array_Copy(maxs, corners[6], 3);
+	Math_MakeVector(mins[0], maxs[1], maxs[2], corners[7]);
+
+	// Rotate all edges
+	for (int i=0; i < sizeof(corners); i++) {
+		Math_RotateVector(corners[i], angles, corners[i]);
+	}
+
+	// Apply world offset (after rotation)
+	for (int i=0; i < sizeof(corners); i++) {
+		AddVectors(origin, corners[i], corners[i]);
+	}
+
+    // Draw all the edges
+	// Horizontal Lines
+	// Bottom
+	for (int i=0; i < 4; i++) {
+		int j = ( i == 3 ? 0 : i+1 );
+		TE_SetupBeamPoints(corners[i], corners[j], modelIndex, haloIndex, startFrame, frameRate, life, width, endWidth, fadeLength, amplitude, color, speed);
+		TE_Send(clients, numClients);
+	}
+
+	// Top
+	for (int i=4; i < 8; i++) {
+		int j = ( i == 7 ? 4 : i+1 );
+		TE_SetupBeamPoints(corners[i], corners[j], modelIndex, haloIndex, startFrame, frameRate, life, width, endWidth, fadeLength, amplitude, color, speed);
+		TE_Send(clients, numClients);
+	}
+
+	// All Vertical Lines
+	for (int i=0; i < 4; i++) {
+		TE_SetupBeamPoints(corners[i], corners[i+4], modelIndex, haloIndex, startFrame, frameRate, life, width, endWidth, fadeLength, amplitude, color, speed);
+		TE_Send(clients, numClients);
+	}
+}
+
+/**
+ * Displays the given axis of rotation as beam effect to one player.
+ *
+ * @param client        The client to show the box to.
+ * @param origin 		Origin/center of the box.
+ * @param angles 		Angles used to rotate the box.
+ * @param length 		The length in each direction.
+ * @param modelIndex	Precached model index.
+ * @param haloIndex		Precached model index.
+ * @param startFrame	Initital frame to render.
+ * @param frameRate		Beam frame rate.
+ * @param life			Time duration of the beam.
+ * @param width			Initial beam width.
+ * @param endWidth		Final beam width.
+ * @param fadeLength	Beam fade time duration.
+ * @param amplitude		Beam amplitude.
+ * @param color			Color array (r, g, b, a).
+ * @param speed			Speed of the beam.
+ */
+stock void Effect_DrawAxisOfRotationToClient(
+	int client,
+	const float origin[3],
+	const float angles[3],
+	const float length[3],
+	int modelIndex,
+	int haloIndex,
+	int startFrame=0,
+	int frameRate=30,
+	float life=5.0,
+	float width=5.0,
+	float endWidth=5.0,
+	int fadeLength=2,
+	float amplitude=1.0,
+	int speed=0
+) {
+    int clients[1];
+    clients[0] = client;
+    Effect_DrawAxisOfRotation(clients, 1, origin, angles, length, modelIndex, haloIndex, startFrame, frameRate, life, width, endWidth, fadeLength, amplitude, speed);
+}
+
+/**
+ * Displays the given axis of rotation as beam effect to all players.
+ *
+ * @param origin 		Origin/center of the box.
+ * @param angles 		Angles used to rotate the box.
+ * @param length 		The length in each direction.
+ * @param modelIndex	Precached model index.
+ * @param haloIndex		Precached model index.
+ * @param startFrame	Initital frame to render.
+ * @param frameRate		Beam frame rate.
+ * @param life			Time duration of the beam.
+ * @param width			Initial beam width.
+ * @param endWidth		Final beam width.
+ * @param fadeLength	Beam fade time duration.
+ * @param amplitude		Beam amplitude.
+ * @param color			Color array (r, g, b, a).
+ * @param speed			Speed of the beam.
+ */
+stock void Effect_DrawAxisOfRotationToAll(
+	const float origin[3],
+	const float angles[3],
+	const float length[3],
+	int modelIndex,
+	int haloIndex,
+	int startFrame=0,
+	int frameRate=30,
+	float life=5.0,
+	float width=5.0,
+	float endWidth=5.0,
+	int fadeLength=2,
+	float amplitude=1.0,
+	int speed=0
+)
+{
+	int[] clients = new int[MaxClients];
+	int numClients = Client_Get(clients, CLIENTFILTER_INGAME);
+
+	Effect_DrawAxisOfRotation(clients, numClients, origin, angles, length, modelIndex, haloIndex, startFrame, frameRate, life, width, endWidth, fadeLength, amplitude, speed);
+}
+
+/**
+ * Displays the given axis of rotation as beam effect to a list of players.
+ *
+ * @param clients       An array of clients to show the box to.
+ * @param numClients    Number of players in the array.
+ * @param origin 		Origin/center of the box.
+ * @param angles 		Angles used to rotate the box.
+ * @param length 		The length in each direction.
+ * @param modelIndex	Precached model index.
+ * @param haloIndex		Precached model index.
+ * @param startFrame	Initital frame to render.
+ * @param frameRate		Beam frame rate.
+ * @param life			Time duration of the beam.
+ * @param width			Initial beam width.
+ * @param endWidth		Final beam width.
+ * @param fadeLength	Beam fade time duration.
+ * @param amplitude		Beam amplitude.
+ * @param color			Color array (r, g, b, a).
+ * @param speed			Speed of the beam.
+ */
+stock void Effect_DrawAxisOfRotation(
+	int[] clients,
+	int numClients,
+	const float origin[3],
+	const float angles[3],
+	const float length[3],
+	int modelIndex,
+	int haloIndex,
+	int startFrame=0,
+	int frameRate=30,
+	float life=5.0,
+	float width=5.0,
+	float endWidth=5.0,
+	int fadeLength=2,
+	float amplitude=1.0,
+	int speed=0
+) {
+	// Create the additional corners of the box
+	float xAxis[3], yAxis[3], zAxis[3];
+	xAxis[0] = length[0];
+	yAxis[1] = length[1];
+	zAxis[2] = length[2];
+
+	// Rotate all edges
+	Math_RotateVector(xAxis, angles, xAxis);
+	Math_RotateVector(yAxis, angles, yAxis);
+	Math_RotateVector(zAxis, angles, zAxis);
+
+	// Apply world offset (after rotation)
+	AddVectors(origin, xAxis, xAxis);
+	AddVectors(origin, yAxis, yAxis);
+	AddVectors(origin, zAxis, zAxis);
+
+    // Draw all
+	TE_SetupBeamPoints(origin, xAxis, modelIndex, haloIndex, startFrame, frameRate, life, width, endWidth, fadeLength, amplitude, {255, 0, 0, 255}, speed);
+	TE_Send(clients, numClients);
+
+	TE_SetupBeamPoints(origin, yAxis, modelIndex, haloIndex, startFrame, frameRate, life, width, endWidth, fadeLength, amplitude, {0, 255, 0, 255}, speed);
+	TE_Send(clients, numClients);
+
+	TE_SetupBeamPoints(origin, zAxis, modelIndex, haloIndex, startFrame, frameRate, life, width, endWidth, fadeLength, amplitude, {0, 0, 255, 255}, speed);
+	TE_Send(clients, numClients);
+}
+
+
+/**
+ * Creates an env_sprite.
+ *
+ * @param origin			Origin of the Sprite.
+ * @param modelIndex		Precached model index.
+ * @param color				Color array (r, g, b, a).
+ * @param scale				Scale (Note: many materials ignore a lower value than 0.25).
+ * @param targetName		Targetname of the sprite.
+ * @param parent			Entity Index of this sprite's parent in the movement hierarchy.
+ * @param renderMode		Render mode (use the enum).
+ * @param renderFx			Render fx (use the enum).
+ * @param glowProxySize		Radius size of the glow when to be rendered, if inside a geometry. Ex: a block 2x2x2 units big, if the glowProxySize is between 0.0 and 2.0 the sprite will not be rendered, even if the actual size of the sprite is bigger, everything above 2.0 will render the sprite. Using an abnormal high value will render Sprites trough walls.
+ * @param frameRate			Sprite frame rate.
+ * @param hdrColorScale 	Float value to multiply sprite color by when running with HDR.
+ * @param receiveShadows	When false then this prevents the sprite from receiving shadows.
+ * @return					Entity Index of the created Sprite.
+ */
+stock int Effect_EnvSprite(
+	const float origin[3],
+	int modelIndex,
+	const int color[4]={255, 255, 255, 255},
+	float scale=0.25,
+	const char targetName[MAX_NAME_LENGTH]="",
+	int parent=-1,
+	RenderMode renderMode=RENDER_WORLDGLOW,
+	RenderFx renderFx=RENDERFX_NONE,
+	float glowProxySize=2.0,
+	float framerate=10.0,
+	float hdrColorScale=1.0,
+	bool receiveShadows = true
+) {
+	int entity = Entity_Create("env_sprite");
+
+	if (entity == INVALID_ENT_REFERENCE) {
+		return INVALID_ENT_REFERENCE;
+	}
+
+	DispatchKeyValue		(entity, "disablereceiveshadows", (receiveShadows) ? "0" : "1");
+	DispatchKeyValueFloat	(entity, "framerate", framerate);
+	DispatchKeyValueFloat	(entity, "GlowProxySize", glowProxySize);
+	DispatchKeyValue		(entity, "spawnflags", "1");
+	DispatchKeyValueFloat	(entity, "HDRColorScale", hdrColorScale);
+	DispatchKeyValue		(entity, "maxdxlevel", "0");
+	DispatchKeyValue		(entity, "mindxlevel", "0");
+	DispatchKeyValueFloat	(entity, "scale", scale);
+
+	DispatchSpawn(entity);
+
+	SetEntityRenderMode(entity, renderMode);
+	SetEntityRenderColor(entity, color[0], color[1], color[2], color[3]);
+	SetEntityRenderFx(entity, renderFx);
+
+	Entity_SetName(entity, targetName);
+	Entity_SetModelIndex(entity, modelIndex);
+	Entity_SetAbsOrigin(entity, origin);
+
+	if (parent != -1) {
+		Entity_SetParent(entity, parent);
+	}
+
+	return entity;
+}

scripting/include/smlib/files.inc

@@ -0,0 +1,451 @@
+#if defined _smlib_files_included
+	#endinput
+#endif
+#define _smlib_files_included
+
+#include <sourcemod>
+#include <sdktools>
+#include <smlib/arrays>
+
+/**
+ * Gets the Base name of a path.
+ * Examples:
+ * blub.txt -> "blub.txt"
+ * /sourcemod/extensions/example.ext.so -> "example.ext.so"
+ *
+ * @param path			File path
+ * @param buffer		String buffer array
+ * @param size			Size of string buffer
+ */
+stock void File_GetBaseName(const char[] path, char[] buffer, int size)
+{
+	if (path[0] == '\0') {
+		buffer[0] = '\0';
+		return;
+	}
+
+	int pos_start = FindCharInString(path, '/', true);
+
+	if (pos_start == -1) {
+		pos_start = FindCharInString(path, '\\', true);
+	}
+
+	pos_start++;
+
+	strcopy(buffer, size, path[pos_start]);
+}
+
+/**
+ * Gets the Directory of a path (without the file name).
+ * Does not work with "." as the path.
+ * Examples:
+ * blub.txt -> "blub.txt"
+ * /sourcemod/extensions/example.ext.so -> "example.ext.so"
+ *
+ * @param path			File path
+ * @param buffer		String buffer array
+ * @param size			Size of string buffer
+ */
+stock void File_GetDirName(const char[] path, char[] buffer, int size)
+{
+	if (path[0] == '\0') {
+		buffer[0] = '\0';
+		return;
+	}
+
+	int pos_start = FindCharInString(path, '/', true);
+
+	if (pos_start == -1) {
+		pos_start = FindCharInString(path, '\\', true);
+
+		if (pos_start == -1) {
+			buffer[0] = '\0';
+			return;
+		}
+	}
+
+	strcopy(buffer, size, path);
+	buffer[pos_start] = '\0';
+}
+
+/**
+ * Gets the File name of a path.
+ * blub.txt -> "blub"
+ * /sourcemod/extensions/example.ext.so -> "example.ext"
+ *
+ * @param path			File path
+ * @param buffer		String buffer array
+ * @param size			Size of string buffer
+ */
+stock void File_GetFileName(const char[] path, char[] buffer, int size)
+{
+	if (path[0] == '\0') {
+		buffer[0] = '\0';
+		return;
+	}
+
+	File_GetBaseName(path, buffer, size);
+
+	int pos_ext = FindCharInString(buffer, '.', true);
+
+	if (pos_ext != -1) {
+		buffer[pos_ext] = '\0';
+	}
+}
+
+/**
+ * Gets the Extension of a file.
+ * Examples:
+ * blub.inc.txt -> "txt"
+ * /sourcemod/extensions/example.ext.so -> "so"
+ *
+ * @param path			Path String
+ * @param buffer		String buffer array
+ * @param size			Max length of string buffer
+ */
+stock void File_GetExtension(const char[] path, char[] buffer, int size)
+{
+	int extpos = FindCharInString(path, '.', true);
+
+	if (extpos == -1) {
+		buffer[0] = '\0';
+		return;
+	}
+
+	strcopy(buffer, size, path[++extpos]);
+}
+
+/**
+ * Adds a path to the downloadables network string table.
+ * This can be a file or directory and also works recursed.
+ * You can optionally specify file extensions that should be ignored.
+ * Bz2 and ztmp are automatically ignored.
+ * It only adds files that actually exist.
+ * You can also specify a wildcard * after the ., very useful for models.
+ * This forces a client to download the file if they do not already have it.
+ *
+ * @param path			Path String
+ * @param recursive		Whether to do recursion or not.
+ * @param ignoreExts	Optional: 2 dimensional String array.You can define it like this: new String:ignore[][] = { ".ext1", ".ext2" };
+ * @param size			This should be set to the number of file extensions in the ignoreExts array (sizeof(ignore) for the example above)
+ */
+
+// Damn you SourcePawn :( I didn't want to
+char _smlib_empty_twodimstring_array[][] = { { '\0' } };
+stock void File_AddToDownloadsTable(const char[] path, bool recursive=true, const char[][] ignoreExts=_smlib_empty_twodimstring_array, int size=0)
+{
+	if (path[0] == '\0') {
+		return;
+	}
+
+	if (FileExists(path)) {
+
+		char fileExtension[5];
+		File_GetExtension(path, fileExtension, sizeof(fileExtension));
+
+		if (StrEqual(fileExtension, "bz2", false) || StrEqual(fileExtension, "ztmp", false)) {
+			return;
+		}
+
+		if (Array_FindString(ignoreExts, size, fileExtension) != -1) {
+			return;
+		}
+
+		char path_new[PLATFORM_MAX_PATH];
+		strcopy(path_new, sizeof(path_new), path);
+		ReplaceString(path_new, sizeof(path_new), "//", "/");
+
+		AddFileToDownloadsTable(path_new);
+	}
+	else if (recursive && DirExists(path)) {
+
+		char dirEntry[PLATFORM_MAX_PATH];
+		DirectoryListing __dir = OpenDirectory(path);
+
+		while (ReadDirEntry(__dir, dirEntry, sizeof(dirEntry))) {
+
+			if (StrEqual(dirEntry, ".") || StrEqual(dirEntry, "..")) {
+				continue;
+			}
+
+			Format(dirEntry, sizeof(dirEntry), "%s/%s", path, dirEntry);
+			File_AddToDownloadsTable(dirEntry, recursive, ignoreExts, size);
+		}
+
+		delete __dir;
+	}
+	else if (FindCharInString(path, '*', true)) {
+
+		char fileExtension[4];
+		File_GetExtension(path, fileExtension, sizeof(fileExtension));
+
+		if (StrEqual(fileExtension, "*")) {
+
+			char dirName[PLATFORM_MAX_PATH],
+				 fileName[PLATFORM_MAX_PATH],
+				 dirEntry[PLATFORM_MAX_PATH];
+
+			File_GetDirName(path, dirName, sizeof(dirName));
+			File_GetFileName(path, fileName, sizeof(fileName));
+			StrCat(fileName, sizeof(fileName), ".");
+
+			DirectoryListing __dir = OpenDirectory(dirName);
+			while (ReadDirEntry(__dir, dirEntry, sizeof(dirEntry))) {
+
+				if (StrEqual(dirEntry, ".") || StrEqual(dirEntry, "..")) {
+					continue;
+				}
+
+				if (strncmp(dirEntry, fileName, strlen(fileName)) == 0) {
+					Format(dirEntry, sizeof(dirEntry), "%s/%s", dirName, dirEntry);
+					File_AddToDownloadsTable(dirEntry, recursive, ignoreExts, size);
+				}
+			}
+
+			delete __dir;
+		}
+	}
+}
+
+
+/*
+ * Adds all files/paths in the given text file to the download table.
+ * Recursive mode enabled, see File_AddToDownloadsTable()
+ * Comments are allowed ! Supported comment types are ; // #
+ *
+ * @param path			Path to the .txt file.
+ */
+stock void File_ReadDownloadList(const char[] path)
+{
+	File file = OpenFile(path, "r");
+
+	if (file  == INVALID_HANDLE) {
+		return;
+	}
+
+	char buffer[PLATFORM_MAX_PATH];
+	while (!IsEndOfFile(file)) {
+		ReadFileLine(file, buffer, sizeof(buffer));
+
+		int pos;
+		pos = StrContains(buffer, "//");
+		if (pos != -1) {
+			buffer[pos] = '\0';
+		}
+
+		pos = StrContains(buffer, "#");
+		if (pos != -1) {
+			buffer[pos] = '\0';
+		}
+
+		pos = StrContains(buffer, ";");
+		if (pos != -1) {
+			buffer[pos] = '\0';
+		}
+
+		TrimString(buffer);
+
+		if (buffer[0] == '\0') {
+			continue;
+		}
+
+		File_AddToDownloadsTable(buffer);
+	}
+
+	delete file;
+}
+
+/*
+ * Attempts to load a translation file and optionally unloads the plugin if the file
+ * doesn't exist (also prints an error message).
+ *
+ * @param file			Filename of the translations file (eg. <pluginname>.phrases).
+ * @param setFailState	If true, it sets the failstate if the translations file doesn't exist
+ * @return				True on success, false otherwise (only if setFailState is set to false)
+ */
+stock bool File_LoadTranslations(const char[] file, bool setFailState=true)
+{
+	char path[PLATFORM_MAX_PATH];
+
+	BuildPath(Path_SM, path, sizeof(path), "translations/%s", file);
+
+	if (FileExists(path)) {
+		LoadTranslations(file);
+		return true;
+	}
+
+	Format(path,sizeof(path), "%s.txt", path);
+
+	if (!FileExists(path)) {
+
+		if (setFailState) {
+			SetFailState("Unable to locate translation file (%s).", path);
+		}
+
+		return false;
+	}
+
+	LoadTranslations(file);
+
+	return true;
+}
+
+/*
+ * Reads the contents of a given file into a string buffer in binary mode.
+ *
+ * @param path		Path to the file
+ * @param buffer	String buffer
+ * @param size		If -1, reads until a null terminator is encountered in the file.  Otherwise, read_count bytes are read into the buffer provided.  In this case the buffer is not explicitly null terminated, and the buffer will contain any null terminators read from the file.
+ * @return			Number of characters written to the buffer, or -1 if an error was encountered.
+ */
+stock int File_ToString(const char[] path, char[] buffer, int size)
+{
+	File file = OpenFile(path, "rb");
+
+	if (file == INVALID_HANDLE) {
+		buffer[0] = '\0';
+		return -1;
+	}
+
+	int num_bytes_written = ReadFileString(file, buffer, size);
+	delete file;
+
+	return num_bytes_written;
+}
+
+/*
+ * Writes a string into a file in binary mode.
+ *
+ * @param file		Path to the file
+ * @param str		String to write
+ * @return			True on success, false otherwise
+ */
+stock bool File_StringToFile(const char[] path, char[] str)
+{
+	File file = OpenFile(path, "wb");
+
+	if (file == INVALID_HANDLE) {
+		return false;
+	}
+
+	bool success = WriteFileString(file, str, false);
+	delete file;
+
+	return success;
+}
+
+/*
+ * Copies file source to destination
+ * Based on code of javalia:
+ * http://forums.alliedmods.net/showthread.php?t=159895
+ *
+ * @param source		Input file
+ * @param destination	Output file
+ * @return				True on success, false otherwise
+ */
+stock bool File_Copy(const char[] source, const char[] destination)
+{
+	File file_source = OpenFile(source, "rb");
+
+	if (file_source == INVALID_HANDLE) {
+		return false;
+	}
+
+	File file_destination = OpenFile(destination, "wb");
+
+	if (file_destination == INVALID_HANDLE) {
+		delete file_source;
+		return false;
+	}
+
+	int buffer[32];
+	int cache;
+
+	while (!IsEndOfFile(file_source)) {
+		cache = ReadFile(file_source, buffer, sizeof(buffer), 1);
+		WriteFile(file_destination, buffer, cache, 1);
+	}
+
+	delete file_source;
+	delete file_destination;
+
+	return true;
+}
+
+/*
+ * Recursively copies (the content) of a directory or file specified
+ * by "path" to "destination".
+ * Note that because of Sourcemod API limitations this currently does not
+ * takeover the file permissions (it leaves them default).
+ * Links will be resolved.
+ *
+ * @param path			Source path
+ * @param destination	Destination directory (This can only be a directory)
+ * @param stop_on_error	Optional: Set to true to stop on error (ie can't read a file)
+ * @param dirMode		Optional: File mode for directories that will be created (Default = 0755), don't forget to convert FROM octal
+ * @return				True on success, false otherwise
+ */
+stock bool File_CopyRecursive(const char[] path, const char[] destination, bool stop_on_error=false, int dirMode=493)
+{
+	if (FileExists(path)) {
+		return File_Copy(path, destination);
+	}
+	else if (DirExists(path)) {
+		return Sub_File_CopyRecursive(path, destination, stop_on_error, FileType_Directory, dirMode);
+	}
+	else {
+		return false;
+	}
+}
+
+static stock bool Sub_File_CopyRecursive(const char[] path, const char[] destination, bool stop_on_error=false, FileType fileType, int dirMode)
+{
+	if (fileType == FileType_File) {
+		return File_Copy(path, destination);
+	}
+	else if (fileType == FileType_Directory) {
+
+		if (!CreateDirectory(destination, dirMode) && stop_on_error) {
+			return false;
+		}
+
+		DirectoryListing directory = OpenDirectory(path);
+
+		if (directory == INVALID_HANDLE) {
+			return false;
+		}
+
+		char
+			source_buffer[PLATFORM_MAX_PATH],
+			destination_buffer[PLATFORM_MAX_PATH];
+		FileType type;
+
+		while (ReadDirEntry(directory, source_buffer, sizeof(source_buffer), type)) {
+
+			if (StrEqual(source_buffer, "..") || StrEqual(source_buffer, ".")) {
+				continue;
+			}
+
+			Format(destination_buffer, sizeof(destination_buffer), "%s/%s", destination, source_buffer);
+			Format(source_buffer, sizeof(source_buffer), "%s/%s", path, source_buffer);
+
+			if (type == FileType_File) {
+				File_Copy(source_buffer, destination_buffer);
+			}
+			else if (type == FileType_Directory) {
+
+				if (!File_CopyRecursive(source_buffer, destination_buffer, stop_on_error, dirMode) && stop_on_error) {
+					delete directory;
+					return false;
+				}
+			}
+		}
+
+		delete directory;
+	}
+	else if (fileType == FileType_Unknown) {
+		return false;
+	}
+
+	return true;
+}

scripting/include/smlib/game.inc

@@ -0,0 +1,57 @@
+#if defined _smlib_game_included
+	#endinput
+#endif
+#define _smlib_game_included
+
+#include <sourcemod>
+#include <sdktools_functions>
+#include <sdktools_entinput>
+
+/*
+ * End's the game and displays the scoreboard with intermission time.
+ *
+ * @return				True on success, false otherwise
+ */
+stock bool Game_End()
+{
+	int game_end = FindEntityByClassname(-1, "game_end");
+
+	if (game_end == -1) {
+		game_end = CreateEntityByName("game_end");
+
+		if (game_end == -1) {
+			ThrowError("Unable to find or create entity \"game_end\"");
+		}
+	}
+
+	return AcceptEntityInput(game_end, "EndGame");
+}
+
+/*
+ * End's the current round, allows specifying the winning
+ * team and more.
+ * This function currently works in TF2 only (it uses the game_round_win entity).
+ *
+ * @param team			The winning Team, pass 0 for Sudden Death mode (no winning team)
+ * @param forceMapReset If to force the map to reset during the force respawn after the round is over.
+ * @param switchTeams	If to switch the teams when the game is going to be reset.
+ * @return				True on success, false otherwise
+ */
+stock bool Game_EndRound(int team=0, bool forceMapReset=false, bool switchTeams=false)
+{
+	int game_round_win = FindEntityByClassname(-1, "game_round_win");
+
+	if (game_round_win == -1) {
+		game_round_win = CreateEntityByName("game_round_win");
+
+		if (game_round_win == -1) {
+			ThrowError("Unable to find or create entity \"game_round_win\"");
+		}
+	}
+
+	DispatchKeyValue(game_round_win, "TeamNum"			, (team			? "true" : "false"));
+	DispatchKeyValue(game_round_win, "force_map_reset"	, (forceMapReset? "true" : "false"));
+	DispatchKeyValue(game_round_win, "switch_teams"		, (switchTeams	? "true" : "false"));
+
+	return AcceptEntityInput(game_round_win, "RoundWin");
+}

scripting/include/smlib/general.inc

@@ -0,0 +1,251 @@
+#if defined _smlib_general_included
+	#endinput
+#endif
+#define _smlib_general_included
+
+#include <sourcemod>
+#include <sdktools_stringtables>
+#include <smlib/math>
+
+#define TIME_TO_TICKS(%1)	( (int)( 0.5 + (float)(%1) / GetTickInterval() ) )
+#define TICKS_TO_TIME(%1)	( GetTickInterval() * %1 )
+#define ROUND_TO_TICKS(%1)	( TICK_INTERVAL * TIME_TO_TICKS( %1 ) )
+
+/*
+ * Precaches the given model.
+ * It's best to call this OnMapStart().
+ *
+ * @param material			Path of the material to precache.
+ * @return					Returns the material index, INVALID_STRING_INDEX on error.
+ */
+stock int PrecacheMaterial(const char[] material)
+{
+	static int materialNames = INVALID_STRING_TABLE;
+
+	if (materialNames == INVALID_STRING_TABLE) {
+		if ((materialNames = FindStringTable("Materials")) == INVALID_STRING_TABLE) {
+			return INVALID_STRING_INDEX;
+		}
+	}
+
+	int index = FindStringIndex2(materialNames, material);
+	if (index == INVALID_STRING_INDEX) {
+		int numStrings = GetStringTableNumStrings(materialNames);
+		if (numStrings >= GetStringTableMaxStrings(materialNames)) {
+			return INVALID_STRING_INDEX;
+		}
+
+		AddToStringTable(materialNames, material);
+		index = numStrings;
+	}
+
+	return index;
+}
+
+/*
+ * Checks if the material is precached.
+ *
+ * @param material			Path of the material.
+ * @return					True if it is precached, false otherwise.
+ */
+stock bool IsMaterialPrecached(const char[] material)
+{
+	static int materialNames = INVALID_STRING_TABLE;
+
+	if (materialNames == INVALID_STRING_TABLE) {
+		if ((materialNames = FindStringTable("Materials")) == INVALID_STRING_TABLE) {
+			return false;
+		}
+	}
+
+	return (FindStringIndex2(materialNames, material) != INVALID_STRING_INDEX);
+}
+
+/*
+ * Precaches the given particle system.
+ * It's best to call this OnMapStart().
+ * Code based on Rochellecrab's, thanks.
+ *
+ * @param particleSystem	Name of the particle system to precache.
+ * @return					Returns the particle system index, INVALID_STRING_INDEX on error.
+ */
+stock int PrecacheParticleSystem(const char[] particleSystem)
+{
+	static int particleEffectNames = INVALID_STRING_TABLE;
+
+	if (particleEffectNames == INVALID_STRING_TABLE) {
+		if ((particleEffectNames = FindStringTable("ParticleEffectNames")) == INVALID_STRING_TABLE) {
+			return INVALID_STRING_INDEX;
+		}
+	}
+
+	int index = FindStringIndex2(particleEffectNames, particleSystem);
+	if (index == INVALID_STRING_INDEX) {
+		int numStrings = GetStringTableNumStrings(particleEffectNames);
+		if (numStrings >= GetStringTableMaxStrings(particleEffectNames)) {
+			return INVALID_STRING_INDEX;
+		}
+
+		AddToStringTable(particleEffectNames, particleSystem);
+		index = numStrings;
+	}
+
+	return index;
+}
+
+/*
+ * Checks if the particle system is precached.
+ *
+ * @param material			Name of the particle system
+ * @return					True if it is precached, false otherwise.
+ */
+stock bool IsParticleSystemPrecached(const char[] particleSystem)
+{
+	static int particleEffectNames = INVALID_STRING_TABLE;
+
+	if (particleEffectNames == INVALID_STRING_TABLE) {
+		if ((particleEffectNames = FindStringTable("ParticleEffectNames")) == INVALID_STRING_TABLE) {
+			return false;
+		}
+	}
+
+	return (FindStringIndex2(particleEffectNames, particleSystem) != INVALID_STRING_INDEX);
+}
+
+/*
+ * Searches for the index of a given string in a string table.
+ *
+ * @param table			String table name.
+ * @param str			String to find.
+ * @return				String index if found, INVALID_STRING_INDEX otherwise.
+ */
+stock int FindStringIndexByTableName(const char[] table, const char[] str)
+{
+	int tableIndex = INVALID_STRING_TABLE;
+	if ((tableIndex = FindStringTable("ParticleEffectNames")) == INVALID_STRING_TABLE) {
+		return INVALID_STRING_INDEX;
+	}
+
+	return FindStringIndex2(tableIndex, str);
+}
+
+/*
+ * Rewrite of FindStringIndex, because in my tests
+ * FindStringIndex failed to work correctly.
+ * Searches for the index of a given string in a string table.
+ *
+ * @param tableidx		A string table index.
+ * @param str			String to find.
+ * @return				String index if found, INVALID_STRING_INDEX otherwise.
+ */
+stock int FindStringIndex2(int tableidx, const char[] str)
+{
+	char buf[1024];
+
+	int numStrings = GetStringTableNumStrings(tableidx);
+	for (int i=0; i < numStrings; i++) {
+		ReadStringTable(tableidx, i, buf, sizeof(buf));
+
+		if (StrEqual(buf, str)) {
+			return i;
+		}
+	}
+
+	return INVALID_STRING_INDEX;
+}
+
+/*
+ * Converts a long IP to a dotted format String.
+ *
+ * @param ip			IP Long
+ * @param buffer		String Buffer (size = 16)
+ * @param size			String Buffer size
+ */
+stock void LongToIP(int ip, char[] buffer, int size)
+{
+	Format(
+		buffer, size,
+		"%d.%d.%d.%d",
+			(ip >> 24)	& 0xFF,
+			(ip >> 16)	& 0xFF,
+			(ip >> 8 )	& 0xFF,
+			ip        	& 0xFF
+		);
+}
+
+/*
+ * Converts a dotted format String IP to a long.
+ *
+ * @param ip			IP String
+ * @return				Long IP
+ */
+stock int IPToLong(const char[] ip)
+{
+	char pieces[4][4];
+
+	if (ExplodeString(ip, ".", pieces, sizeof(pieces), sizeof(pieces[])) != 4) {
+		return 0;
+	}
+
+	return (
+		StringToInt(pieces[0]) << 24	|
+		StringToInt(pieces[1]) << 16	|
+		StringToInt(pieces[2]) << 8		|
+		StringToInt(pieces[3])
+	);
+}
+
+static int localIPRanges[] =
+{
+	10	<< 24,				// 10.
+	127	<< 24 | 1		,	// 127.0.0.1
+	127	<< 24 | 16	<< 16,	// 127.16.
+	192	<< 24 | 168	<< 16,	// 192.168.
+};
+
+/*
+ * Checks whether an IP is a private/internal IP
+ *
+ * @param ip			IP Long
+ * @return				True if the IP is local, false otherwise.
+ */
+stock bool IsIPLocal(int ip)
+{
+	int range, bits, move;
+	bool matches;
+
+	for (int i=0; i < sizeof(localIPRanges); i++) {
+
+		range = localIPRanges[i];
+		matches = true;
+
+		for (int j=0; j < 4; j++) {
+			move = j * 8;
+			bits = (range >> move) & 0xFF;
+
+			if (bits && bits != ((ip >> move) & 0xFF)) {
+				matches = false;
+			}
+		}
+
+		if (matches) {
+			return true;
+		}
+	}
+
+	return false;
+}
+
+/*
+ * Closes the given hindle and sets it to INVALID_HANDLE.
+ * Obsolete now. Just use |delete handle|.
+ *
+ * @param handle   handle
+ */
+stock void ClearHandle(Handle &handle)
+{
+	if (handle != INVALID_HANDLE) {
+		CloseHandle(handle);
+		handle = INVALID_HANDLE;
+	}
+}

scripting/include/smlib/math.inc

@@ -0,0 +1,346 @@
+#if defined _smlib_math_included
+	#endinput
+#endif
+#define _smlib_math_included
+
+#include <sourcemod>
+
+#define SIZE_OF_INT         2147483647 // without 0
+#define INT_MAX_DIGITS      10
+
+#define GAMEUNITS_TO_METERS	0.01905
+#define METERS_TO_GAMEUNITS	52.49343832020997
+#define METERS_TO_FEET		3.2808399
+#define FEET_TO_METERS		0.3048
+#define KILOMETERS_TO_MILES	0.62137
+
+enum VecAngle
+{
+	ANG_ALPHA,
+	ANG_BETA,
+	ANG_GAMMA
+};
+
+/**
+ * Makes a negative integer number to a positive integer number.
+ * This is faster than Sourcemod's native FloatAbs() for integers.
+ * Use FloatAbs() for Float numbers.
+ *
+ * @param number		A number that can be positive or negative.
+ * @return				Positive number.
+ */
+stock int Math_Abs(int value)
+{
+	return (value ^ (value >> 31)) - (value >> 31);
+}
+
+/**
+ * Checks if 2 vectors are equal.
+ * You can specfiy a tolerance, which is the maximum distance at which vectors are considered equals
+ *
+ * @param vec1			First vector (3 dim array)
+ * @param vec2			Second vector (3 dim array)
+ * @param tolerance 	If you want to check that those vectors are somewhat even. 0.0 means they are 100% even if this function returns true.
+ * @return				True if vectors are equal, false otherwise.
+ */
+stock bool Math_VectorsEqual(float vec1[3], float vec2[3], float tolerance=0.0)
+{
+	float distance = GetVectorDistance(vec1, vec2, true);
+
+	return distance <= (tolerance * tolerance);
+}
+
+/**
+ * Sets the given value to min
+ * if the value is smaller than the given.
+ * Don't use this with float values.
+ *
+ * @param value			Value
+ * @param min			Min Value used as lower border
+ * @return				Correct value not lower than min
+ */
+stock any Math_Min(any value, any min)
+{
+	if (value < min) {
+		value = min;
+	}
+
+	return value;
+}
+
+/**
+ * Sets the given value to max
+ * if the value is greater than the given.
+ * Don't use this with float values.
+ *
+ * @param value			Value
+ * @param max			Max Value used as upper border
+ * @return				Correct value not upper than max
+ */
+stock any Math_Max(any value, any max)
+{
+	if (value > max) {
+		value = max;
+	}
+
+	return value;
+}
+
+/**
+ * Makes sure a value is within a certain range and
+ * returns the value.
+ * If the value is outside the range it is set to either
+ * min or max, if it is inside the range it will just return
+ * the specified value.
+ * Don't use this with float values.
+ *
+ * @param value			Value
+ * @param min			Min value used as lower border
+ * @param max			Max value used as upper border
+ * @return				Correct value not lower than min and not greater than max.
+ */
+stock any Math_Clamp(any value, any min, any max)
+{
+	value = Math_Min(value, min);
+	value = Math_Max(value, max);
+
+	return value;
+}
+
+/*
+ * Checks if the value is within the given bounds (min & max).
+ * Don't use this with float values.
+ *
+ * @param value		The value you want to check.
+ * @param min		The lower border.
+ * @param max		The upper border.
+ * @return			True if the value is within bounds (bigger or equal min / smaller or equal max), false otherwise.
+ */
+stock bool Math_IsInBounds(any value, any min, any max)
+{
+	if (value < min || value > max) {
+		return false;
+	}
+
+	return true;
+}
+
+/**
+ * Let's the specified value "overflow" if it is outside the given limit.
+ * This is like with integers when it reaches a value above the max possible
+ * integer size.
+ * Don't use this with float values.
+ *
+ * @param value			Value
+ * @param min			Min value used as lower border
+ * @param max			Max value used as upper border
+ * @return				Overflowed number
+ */
+stock any Math_Overflow(any value, any min, any max)
+{
+	return (value % max) + min;
+}
+
+/**
+ * Returns a random, uniform Integer number in the specified (inclusive) range.
+ * This is safe to use multiple times in a function.
+ * The seed is set automatically for each plugin.
+ * Rewritten by MatthiasVance, thanks.
+ *
+ * @param min			Min value used as lower border
+ * @param max			Max value used as upper border
+ * @return				Random Integer number between min and max
+ */
+stock int Math_GetRandomInt(int min, int max)
+{
+	int random = GetURandomInt();
+
+	if (random == 0) {
+		random++;
+	}
+
+	return RoundToCeil(float(random) / (float(SIZE_OF_INT) / float(max - min + 1))) + min - 1;
+}
+
+/**
+ * Returns a random, uniform Float number in the specified (inclusive) range.
+ * This is safe to use multiple times in a function.
+ * The seed is set automatically for each plugin.
+ *
+ * @param min			Min value used as lower border
+ * @param max			Max value used as upper border
+ * @return				Random Float number between min and max
+ */
+stock float Math_GetRandomFloat(float min, float max)
+{
+	return (GetURandomFloat() * (max  - min)) + min;
+}
+
+/**
+ * Gets the percentage of amount in all as Integer where
+ * amount and all are numbers and amount usually
+ * is a subset of all.
+ *
+ * @param value			Integer value
+ * @param all			Integer value
+ * @return				An Integer value between 0 and 100 (inclusive).
+ */
+stock int Math_GetPercentage(int value, int all) {
+	return RoundToNearest((float(value) / float(all)) * 100.0);
+}
+
+/**
+ * Gets the percentage of amount in all as Float where
+ * amount and all are numbers and amount usually
+ * is a subset of all.
+ *
+ * @param value			Float value
+ * @param all			Float value
+ * @return				A Float value between 0.0 and 100.0 (inclusive).
+ */
+stock float Math_GetPercentageFloat(float value, float all) {
+	return (value / all) * 100.0;
+}
+
+/*
+ * Moves the start vector on a direct line to the end vector by the given scale.
+ * Note: If scale is 0.0 the output will be the same as the start vector and if scale is 1.0 the output vector will be the same as the end vector.
+ * Exmaple usage: Move an entity to another entity but only 12 units: Vector_MoveVector(entity1Origin,entity2Origin,(12.0 / GetVectorDistance(entity1Origin,entity2Origin)),newEntity1Origin); now only teleport your entity to newEntity1Origin.
+ *
+ * @param start			The start vector where the imagined line starts.
+ * @param end			The end vector where the imagined line ends.
+ * @param scale			The position on the line 0.0 is the start 1.0 is the end.
+ * @param output		Output vector
+ */
+stock void Math_MoveVector(const float start[3], const float end[3], float scale, float output[3])
+{
+	SubtractVectors(end,start,output);
+	ScaleVector(output,scale);
+	AddVectors(start,output,output);
+}
+
+/**
+ * Puts x, y and z into a vector.
+ *
+ * @param x				Float value.
+ * @param y				Float value.
+ * @param z				Float value.
+ * @param result		Output vector.
+ */
+stock void Math_MakeVector(float x, float y, float z, float result[3])
+{
+	result[0] = x;
+	result[1] = y;
+	result[2] = z;
+}
+
+/**
+ * Rotates a vector around its zero-point.
+ * Note: As example you can rotate mins and maxs of an entity and then add its origin to mins and maxs to get its bounding box in relation to the world and its rotation.
+ * When used with players use the following angle input:
+ *   angles[0] = 0.0;
+ *   angles[1] = 0.0;
+ *   angles[2] = playerEyeAngles[1];
+ *
+ * @param vec 			Vector to rotate.
+ * @param angles 		How to rotate the vector.
+ * @param result		Output vector.
+ */
+stock void Math_RotateVector(const float vec[3], const float angles[3], float result[3])
+{
+	// First the angle/radiant calculations
+	float rad[3];
+	// I don't really know why, but the alpha, beta, gamma order of the angles are messed up...
+	// 2 = xAxis
+	// 0 = yAxis
+	// 1 = zAxis
+	rad[0] = DegToRad(angles[2]);
+	rad[1] = DegToRad(angles[0]);
+	rad[2] = DegToRad(angles[1]);
+
+	// Pre-calc function calls
+	float cosAlpha = Cosine(rad[0]);
+	float sinAlpha = Sine(rad[0]);
+	float cosBeta = Cosine(rad[1]);
+	float sinBeta = Sine(rad[1]);
+	float cosGamma = Cosine(rad[2]);
+	float sinGamma = Sine(rad[2]);
+
+	// 3D rotation matrix for more information: http://en.wikipedia.org/wiki/Rotation_matrix#In_three_dimensions
+	float x = vec[0], y = vec[1], z = vec[2];
+	float newX, newY, newZ;
+	newY = cosAlpha*y - sinAlpha*z;
+	newZ = cosAlpha*z + sinAlpha*y;
+	y = newY;
+	z = newZ;
+
+	newX = cosBeta*x + sinBeta*z;
+	newZ = cosBeta*z - sinBeta*x;
+	x = newX;
+	z = newZ;
+
+	newX = cosGamma*x - sinGamma*y;
+	newY = cosGamma*y + sinGamma*x;
+	x = newX;
+	y = newY;
+
+	// Store everything...
+	result[0] = x;
+	result[1] = y;
+	result[2] = z;
+}
+
+/**
+ * Converts Source Game Units to metric Meters
+ *
+ * @param units			Float value
+ * @return				Meters as Float value.
+ */
+stock float Math_UnitsToMeters(float units)
+{
+	return (units * GAMEUNITS_TO_METERS);
+}
+
+/**
+ * Converts Source Game Units to Meters
+ *
+ * @param units			Float value
+ * @return				Feet as Float value.
+ */
+stock float Math_UnitsToFeet(float units)
+{
+	return (Math_UnitsToMeters(units) * METERS_TO_FEET);
+}
+
+/**
+ * Converts Source Game Units to Centimeters
+ *
+ * @param units			Float value
+ * @return				Centimeters as Float value.
+ */
+stock float Math_UnitsToCentimeters(float units)
+{
+	return (Math_UnitsToMeters(units) * 100.0);
+}
+
+/**
+ * Converts Source Game Units to Kilometers
+ *
+ * @param units			Float value
+ * @return				Kilometers as Float value.
+ */
+stock float Math_UnitsToKilometers(float units)
+{
+	return (Math_UnitsToMeters(units) / 1000.0);
+}
+
+/**
+ * Converts Source Game Units to Miles
+ *
+ * @param units			Float value
+ * @return				Miles as Float value.
+ */
+stock float Math_UnitsToMiles(float units)
+{
+	return (Math_UnitsToKilometers(units) * KILOMETERS_TO_MILES);
+}

scripting/include/smlib/menus.inc

@@ -0,0 +1,37 @@
+#if defined _smlib_menus_included
+	#endinput
+#endif
+#define _smlib_menus_included
+
+#include <sourcemod>
+#include <smlib/math>
+
+/**
+ * Adds an option to a menu with a String display but an integer
+ * identifying the option.
+ *
+ * @param   menu        Handle to the menu
+ * @param   value       Integer value for the option
+ * @param   display     Display text for the menu
+ */
+stock void Menu_AddIntItem(Menu menu, any value, char[] display)
+{
+	char buffer[INT_MAX_DIGITS + 1];
+	IntToString(value, buffer, sizeof(buffer));
+	menu.AddItem(buffer, display);
+}
+
+/**
+ * Retrieves an integer-value choice from a menu, where the
+ * menu's information strings were created as integers.
+ *
+ * @param   menu         Handle to the menu
+ * @param   param2       The item position selected from the menu.
+ * @return               Integer choice from the menu, or 0 if the integer could not be parsed.
+ */
+stock any Menu_GetIntItem(Menu menu, any param2)
+{
+	char buffer[INT_MAX_DIGITS + 1];
+	menu.GetItem(param2, buffer, sizeof(buffer));
+	return StringToInt(buffer);
+}

scripting/include/smlib/server.inc

@@ -0,0 +1,135 @@
+#if defined _smlib_server_included
+	#endinput
+#endif
+#define _smlib_server_included
+
+#include <sourcemod>
+#include <smlib/general>
+
+/*
+ * Gets the server's public/external (default) or
+ * private/local (usually server's behind a NAT) IP.
+ * If your server is behind a NAT Router, you need the SteamTools
+ * extension available at http://forums.alliedmods.net/showthread.php?t=129763
+ * to get the public IP. <steamtools> has to be included BEFORE <smlib>.
+ * If the server is not behind NAT, the public IP is the same as the private IP.
+ *
+ * @param public		Set to true to retrieve the server's public/external IP, false otherwise.
+ * @return				Long IP or 0 if the IP couldn't be retrieved.
+ */
+stock int Server_GetIP(bool public_=true)
+{
+	int ip = 0;
+
+	static ConVar cvHostip = null;
+
+	if (cvHostip == INVALID_HANDLE) {
+		cvHostip = FindConVar("hostip");
+		MarkNativeAsOptional("Steam_GetPublicIP");
+	}
+
+	if (cvHostip != INVALID_HANDLE) {
+		ip = cvHostip.IntValue;
+	}
+
+	if (ip != 0 && IsIPLocal(ip) == public_) {
+		ip = 0;
+	}
+
+#if defined _steamtools_included
+	if (ip == 0) {
+		if (CanTestFeatures() && GetFeatureStatus(FeatureType_Native, "Steam_GetPublicIP") == FeatureStatus_Available) {
+			int octets[4];
+			Steam_GetPublicIP(octets);
+
+			ip =
+				octets[0] << 24	|
+				octets[1] << 16	|
+				octets[2] << 8	|
+				octets[3];
+
+			if (IsIPLocal(ip) == public_) {
+				ip = 0;
+			}
+		}
+	}
+#endif
+
+	return ip;
+}
+
+/*
+ * Gets the server's public/external (default) or
+ * private/local (usually server's behind a NAT) as IP String in dotted format.
+ * If your server is behind a NAT Router, you need the SteamTools
+ * extension available at http://forums.alliedmods.net/showthread.php?t=129763
+ * to get the public IP. <steamtools> has to be included BEFORE <smlib>.
+ * If the public IP couldn't be found, an empty String is returned.
+ * If the server is not behind NAT, the public IP is the same as the private IP.
+ *
+ * @param buffer		String buffer (size=16)
+ * @param size			String buffer size.
+ * @param public		Set to true to retrieve the server's public/external IP, false otherwise.
+ * @return				True on success, false otherwise.
+ */
+stock bool Server_GetIPString(char[] buffer, int size, bool public_=true)
+{
+	int ip;
+
+	if ((ip = Server_GetIP(public_)) == 0) {
+		buffer[0] = '\0';
+		return false;
+	}
+
+	LongToIP(ip, buffer, size);
+
+	return true;
+}
+
+/*
+ * Gets the server's local port.
+ *
+ * @noparam
+ * @return			The server's port, 0 if there is no port.
+ */
+stock int Server_GetPort()
+{
+	static ConVar cvHostport = null;
+
+	if (cvHostport == INVALID_HANDLE) {
+		cvHostport = FindConVar("hostport");
+	}
+
+	if (cvHostport == INVALID_HANDLE) {
+		return 0;
+	}
+
+	int port = cvHostport.IntValue;
+
+	return port;
+}
+
+/*
+ * Gets the server's hostname
+ *
+ * @param hostname		String buffer
+ * @param size			String buffer size
+ * @return				True on success, false otherwise.
+ */
+stock bool Server_GetHostName(char[] buffer, int size)
+{
+	static ConVar cvHostname = null;
+
+	if (cvHostname == INVALID_HANDLE) {
+		cvHostname = FindConVar("hostname");
+	}
+
+	if (cvHostname == INVALID_HANDLE) {
+		buffer[0] = '\0';
+		return false;
+	}
+
+	cvHostname.GetString(buffer, size);
+
+	return true;
+}

scripting/include/smlib/sql.inc

@@ -0,0 +1,107 @@
+#if defined _smlib_sql_included
+	#endinput
+#endif
+#define _smlib_sql_included
+
+#include <sourcemod>
+#include <dbi>
+
+/**
+ * Executes a threaded SQL Query (See: SQL_TQuery)
+ * This function supports the printf Syntax.
+ *
+ *
+ * @param database		A database Handle.
+ * @param callback		Callback; database is in "owner" and the query Handle is passed in "hndl".
+ * @param data			Extra data value to pass to the callback.
+ * @param format		Query string, printf syntax supported
+ * @param priority		Priority queue to use
+ * @param ...			Variable number of format parameters.
+ */
+stock void SQL_TQueryF(Database database, SQLTCallback callback, any data, DBPriority priority=DBPrio_Normal, const char[] format, any ...) {
+
+	if (!database) {
+		ThrowError("[SMLIB] Error: Invalid database handle.");
+		return;
+	}
+
+	char query[16384];
+	VFormat(query, sizeof(query), format, 6);
+
+	SQL_TQuery(database, callback, query, data, priority);
+}
+
+/**
+ * Fetches an integer from a field in the current row of a result set (See: SQL_FetchInt)
+ *
+ * @param query			A query (or statement) Handle.
+ * @param field			The field index (starting from 0).
+ * @param result		Optional variable to store the status of the return value.
+ * @return				An integer value.
+ * @error				Invalid query Handle or field index, invalid
+ *						type conversion requested from the database,
+ *						or no current result set.
+ */
+stock int SQL_FetchIntByName(DBResultSet query, const char[] fieldName, DBResult &result=DBVal_Error) {
+
+	int fieldNum;
+	SQL_FieldNameToNum(query, fieldName, fieldNum);
+
+	return SQL_FetchInt(query, fieldNum, result);
+}
+
+/**
+ * Fetches a bool from a field in the current row of a result set (See: SQL_FetchInt)
+ *
+ * @param query			A query (or statement) Handle.
+ * @param field			The field index (starting from 0).
+ * @param result		Optional variable to store the status of the return value.
+ * @return				A bool value.
+ * @error				Invalid query Handle or field index, invalid
+ *						type conversion requested from the database,
+ *						or no current result set.
+ */
+stock bool SQL_FetchBoolByName(DBResultSet query, const char[] fieldName, DBResult &result=DBVal_Error) {
+
+	return SQL_FetchIntByName(query, fieldName, result) != 0;
+}
+
+/**
+ * Fetches a float from a field in the current row of a result set. (See: SQL_FetchFloat)
+ *
+ * @param query			A query (or statement) Handle.
+ * @param field			The field index (starting from 0).
+ * @param result		Optional variable to store the status of the return value.
+ * @return				A float value.
+ * @error				Invalid query Handle or field index, invalid
+ *						type conversion requested from the database,
+ *						or no current result set.
+ */
+stock float SQL_FetchFloatByName(DBResultSet query, const char[] fieldName, DBResult &result=DBVal_Error) {
+
+	int fieldNum;
+	SQL_FieldNameToNum(query, fieldName, fieldNum);
+
+	return SQL_FetchFloat(query, fieldNum, result);
+}
+
+/**
+ * Fetches a string from a field in the current row of a result set. (See: SQL_FetchString)
+ *
+ * @param query			A query (or statement) Handle.
+ * @param field			The field index (starting from 0).
+ * @param buffer		String buffer.
+ * @param maxlength		Maximum size of the string buffer.
+ * @param result		Optional variable to store the status of the return value.
+ * @return				Number of bytes written.
+ * @error				Invalid query Handle or field index, invalid
+ *						type conversion requested from the database,
+ *						or no current result set.
+ */
+stock int SQL_FetchStringByName(DBResultSet query, const char[] fieldName, char[] buffer, int maxlength, DBResult &result=DBVal_Error) {
+
+	int fieldNum;
+	SQL_FieldNameToNum(query, fieldName, fieldNum);
+
+	return SQL_FetchString(query, fieldNum, buffer, maxlength, result);
+}

scripting/include/smlib/strings.inc

@@ -0,0 +1,228 @@
+#if defined _smlib_strings_included
+	#endinput
+#endif
+#define _smlib_strings_included
+
+#include <sourcemod>
+#include <smlib/math>
+
+/**
+ * Checks if the string is numeric.
+ * This correctly handles + - . in the String.
+ *
+ * @param str				String to check.
+ * @return					True if the String is numeric, false otherwise..
+ */
+stock bool String_IsNumeric(const char[] str)
+{
+	int x=0;
+	int dotsFound=0;
+	int numbersFound=0;
+
+	if (str[x] == '+' || str[x] == '-') {
+		x++;
+	}
+
+	while (str[x] != '\0') {
+
+		if (IsCharNumeric(str[x])) {
+			numbersFound++;
+		}
+		else if (str[x] == '.') {
+			dotsFound++;
+
+			if (dotsFound > 1) {
+				return false;
+			}
+		}
+		else {
+			return false;
+		}
+
+		x++;
+	}
+
+	if (!numbersFound) {
+		return false;
+	}
+
+	return true;
+}
+
+/**
+ * Trims a string by removing the specified chars from beginning and ending.
+ * Removes all ' ', '\t', '\r', '\n' characters by default.
+ * The Output String can be the same as the Input String.
+ *
+ * @param str				Input String.
+ * @param output			Output String (Can be the as the input).
+ * @param size				Size of the output String.
+ * @param chars				Characters to remove.
+ */
+stock void String_Trim(const char[] str, char[] output, int size, const char[] chrs=" \t\r\n")
+{
+	int x=0;
+	while (str[x] != '\0' && FindCharInString(chrs, str[x]) != -1) {
+		x++;
+	}
+
+	x = strcopy(output, size, str[x]);
+	x--;
+
+	while (x >= 0 && FindCharInString(chrs, output[x]) != -1) {
+		x--;
+	}
+
+	output[++x] = '\0';
+}
+
+/**
+ * Removes a list of strings from a string.
+ *
+ * @param buffer			Input/Output buffer.
+ * @param removeList		A list of strings which should be removed from buffer.
+ * @param size				Number of Strings in the List.
+ * @param caseSensitive		If true, comparison is case sensitive. If false (default), comparison is case insensitive.
+ */
+stock void String_RemoveList(char[] buffer, const char[][] removeList, int size, bool caseSensitive=false)
+{
+	for (int i=0; i < size; i++) {
+		ReplaceString(buffer, SIZE_OF_INT, removeList[i], "", caseSensitive);
+	}
+}
+
+/**
+ * Converts the whole String to lower case.
+ * Only works with alphabetical characters (not ÖÄÜ) because Sourcemod suxx !
+ * The Output String can be the same as the Input String.
+ *
+ * @param input				Input String.
+ * @param output			Output String.
+ * @param size				Max Size of the Output string
+ */
+stock void String_ToLower(const char[] input, char[] output, int size)
+{
+	size--;
+
+	int x=0;
+	while (input[x] != '\0' && x < size) {
+
+		output[x] = CharToLower(input[x]);
+
+		x++;
+	}
+
+	output[x] = '\0';
+}
+
+/**
+ * Converts the whole String to upper case.
+ * Only works with alphabetical characters (not öäü) because Sourcemod suxx !
+ * The Output String can be the same as the Input String.
+ *
+ * @param input				Input String.
+ * @param output			Output String.
+ * @param size				Max Size of the Output string
+ */
+stock void String_ToUpper(const char[] input, char[] output, int size)
+{
+	size--;
+
+	int x=0;
+	while (input[x] != '\0' && x < size) {
+
+		output[x] = CharToUpper(input[x]);
+
+		x++;
+	}
+
+	output[x] = '\0';
+}
+
+/**
+ * Generates a random string.
+ *
+ *
+ * @param buffer			String Buffer.
+ * @param size				String Buffer size (must be length+1)
+ * @param length			Number of characters being generated.
+ * @param chrs				String for specifying the characters used for random character generation.
+ * 							By default it will use all letters of the alphabet (upper and lower) and all numbers.
+ * 							If you pass an empty String, it will use all readable ASCII characters (33 - 126)
+ */
+stock void String_GetRandom(char[] buffer, int size, int length=32, const char[] chrs="abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ01234556789")
+{
+	int random, len;
+	size--;
+
+	if (chrs[0] != '\0') {
+		len = strlen(chrs) - 1;
+	}
+
+	int n = 0;
+	while (n < length && n < size) {
+
+		if (chrs[0] == '\0') {
+			random = Math_GetRandomInt(33, 126);
+			buffer[n] = random;
+		}
+		else {
+			random = Math_GetRandomInt(0, len);
+			buffer[n] = chrs[random];
+		}
+
+		n++;
+	}
+
+	buffer[length] = '\0';
+}
+
+/**
+ * Checks if string str starts with subString.
+ *
+ *
+ * @param str				String to check
+ * @param subString			Sub-String to check in str
+ * @return					True if str starts with subString, false otherwise.
+ */
+stock bool String_StartsWith(const char[] str, const char[] subString)
+{
+	int n = 0;
+	while (subString[n] != '\0') {
+
+		if (str[n] == '\0' || str[n] != subString[n]) {
+			return false;
+		}
+
+		n++;
+	}
+
+	return true;
+}
+
+/**
+ * Checks if string str ends with subString.
+ *
+ *
+ * @param str				String to check
+ * @param subString			Sub-String to check in str
+ * @return					True if str ends with subString, false otherwise.
+ */
+stock bool String_EndsWith(const char[] str, const char[] subString)
+{
+	int n_str = strlen(str) - 1;
+	int n_subString = strlen(subString) - 1;
+
+	if(n_str < n_subString) {
+		return false;
+	}
+
+	while (n_str != 0 && n_subString != 0) {
+
+		if (str[n_str--] != subString[n_subString--]) {
+			return false;
+		}
+	}
+
+	return true;
+}

scripting/include/smlib/teams.inc

@@ -0,0 +1,317 @@
+#if defined _smlib_teams_included
+	#endinput
+#endif
+#define _smlib_teams_included
+
+#include <sourcemod>
+#include <smlib/clients>
+#include <smlib/entities>
+
+#define MAX_TEAMS				32	// Max number of teams in a game
+#define MAX_TEAM_NAME_LENGTH	32	// Max length of a team's name
+
+// Team Defines
+#define	TEAM_INVALID	-1
+#define TEAM_UNASSIGNED	0
+#define TEAM_SPECTATOR	1
+#define TEAM_ONE		2
+#define TEAM_TWO		3
+#define TEAM_THREE		4
+#define TEAM_FOUR		5
+
+/*
+ * If one team is empty its assumed single team mode is enabled and the game won't start.
+ *
+ * @noparam
+ * @return			True if one team is empty, false otherwise.
+ */
+stock bool Team_HaveAllPlayers(bool countFakeClients=true) {
+
+	int teamCount = GetTeamCount();
+	for (int i=2; i < teamCount; i++) {
+
+		if (Team_GetClientCount(i, ((countFakeClients) ? CLIENTFILTER_ALL : CLIENTFILTER_NOBOTS)) == 0) {
+			return false;
+		}
+	}
+
+	return true;
+}
+
+/*
+ * Returns the client count of the players in a team.
+ *
+ * @param team					Team Index.
+ * @param flags					Client Filter Flags (Use the CLIENTFILTER_ constants).
+ * @return						Client count in the server.
+ */
+stock int Team_GetClientCount(int team, int flags=0)
+{
+	flags |= CLIENTFILTER_INGAME;
+
+	int numClients = 0;
+	for (int client=1; client <= MaxClients; client++) {
+
+		if (!Client_MatchesFilter(client, flags)) {
+			continue;
+		}
+
+		if (GetClientTeam(client) == team) {
+			numClients++;
+		}
+	}
+
+	return numClients;
+}
+
+/*
+ * Returns the client counts of the first two teams (eg.: Terrorists - Counter).
+ * Use this function for optimization if you have to get the counts of both teams,
+ * otherwise use Team_GetClientCount().
+ *
+ * @param team1					Pass an integer variable by reference
+ * @param team2					Pass an integer variable by reference
+ * @param flags					Client Filter Flags (Use the CLIENTFILTER_ constants).
+ */
+stock void Team_GetClientCounts(int &team1=0, int &team2=0, int flags=0)
+{
+	flags |= CLIENTFILTER_INGAME;
+
+	for (int client=1; client <= MaxClients; client++) {
+
+		if (!Client_MatchesFilter(client, flags)) {
+			continue;
+		}
+
+		if (GetClientTeam(client) == TEAM_ONE) {
+			team1++;
+		}
+		else if (GetClientTeam(client) == TEAM_TWO) {
+			team2++;
+		}
+	}
+}
+
+/*
+ * Gets the name of a team.
+ * Don't call this before OnMapStart()
+ *
+ * @param index			Team Index.
+ * @param str			String buffer
+ * @param size			String Buffer Size
+ * @return				True on success, false otherwise
+ */
+stock bool Team_GetName(int index, char[] str, int size)
+{
+	int edict = Team_GetEdict(index);
+
+	if (edict == -1) {
+		str[0] = '\0';
+		return false;
+	}
+
+	GetEntPropString(edict, Prop_Send, "m_szTeamname", str, size);
+
+	return true;
+}
+
+/*
+ * Changes a team's name.
+ * Use this carefully !
+ * Only set the teamname OnMapStart() or OnEntityCreated()
+ * when no players are ingame, otherwise it can crash the server.
+ *
+ * @param index			Team Index.
+ * @param name			New Name String
+ * @return				True on success, false otherwise
+ */
+stock bool Team_SetName(int index, const char[] name)
+{
+	int edict = Team_GetEdict(index);
+
+	if (edict == -1) {
+		return false;
+	}
+
+	SetEntPropString(edict, Prop_Send, "m_szTeamname", name);
+	ChangeEdictState(edict, GetEntSendPropOffs(edict, "m_szTeamname", true));
+
+	return true;
+}
+
+/*
+ * Changes a team's score.
+ * Don't use this before OnMapStart().
+ *
+ * @param index			Team Index.
+ * @return				Team Score or -1 if the team is not valid.
+ */
+stock int Team_GetScore(int index)
+{
+	int edict = Team_GetEdict(index);
+
+	if (edict == -1) {
+		return -1;
+	}
+
+	return GetEntProp(edict, Prop_Send, "m_iScore");
+}
+
+/*
+ * Changes a team's score.
+ * Don't use this before OnMapStart().
+ *
+ * @param index			Team Index.
+ * @param score			Score value.
+ * @return				True on success, false otherwise
+ */
+stock bool Team_SetScore(int index, int score)
+{
+	int edict = Team_GetEdict(index);
+
+	if (edict == -1) {
+		return false;
+	}
+
+	SetEntProp(edict, Prop_Send, "m_iScore", score);
+
+	ChangeEdictState(edict, GetEntSendPropOffs(edict, "m_iScore", true));
+
+	return true;
+}
+
+/*
+ * Gets a team's edict (*team_manager) Team Index.
+ * Don't call this before OnMapStart()
+ *
+ * @param edict			Edict
+ * @return				Team Index
+ */
+stock int Team_EdictGetNum(int edict)
+{
+	return GetEntProp(edict, Prop_Send, "m_iTeamNum");
+}
+
+/*
+ * Check's whether the index is a valid team index or not.
+ * Don't call this before OnMapStart()
+ *
+ * @param index			Index.
+ * @return				True if the Index is a valid team, false otherwise.
+ */
+stock bool Team_IsValid(int index)
+{
+	return (Team_GetEdict(index) != -1);
+}
+
+/*
+ * Gets a team's edict (team_manager) Team Index.
+ * Don't call this before OnMapStart()
+ *
+ * @param index			Edict
+ * @return				Team Index
+ */
+stock int Team_EdictIsValid(int edict)
+{
+	return GetEntProp(edict, Prop_Send, "m_iTeamNum");
+}
+
+/*
+ * Gets a team's edict (team_manager).
+ * This function caches found team edicts.
+ * Don't call this before OnMapStart()
+ *
+ * @param index			Team Index.
+ * @return				Team edict or -1 if not found
+ */
+stock int Team_GetEdict(int index)
+{
+	static int teams[MAX_TEAMS] = { INVALID_ENT_REFERENCE, ... };
+
+	if (index < 0 || index > MAX_TEAMS) {
+		return -1;
+	}
+
+	int edict = teams[index];
+	if (Entity_IsValid(edict)) {
+		return edict;
+	}
+
+	bool foundTeamManager = false;
+
+	int maxEntities = GetMaxEntities();
+	for (int entity=MaxClients+1; entity < maxEntities; entity++) {
+
+		if (!IsValidEntity(entity)) {
+			continue;
+		}
+
+		if (Entity_ClassNameMatches(entity, "team_manager", true)) {
+			foundTeamManager = true;
+		}
+		// Do not continue when no team managers are found anymore (for optimization)
+		else if (foundTeamManager) {
+			return -1;
+		}
+		else {
+			continue;
+		}
+
+		int num = Team_EdictGetNum(entity);
+
+		if (num >= 0 && num <= MAX_TEAMS) {
+			teams[num] = EntIndexToEntRef(entity);
+		}
+
+		if (num == index) {
+			return entity;
+		}
+	}
+
+	return -1;
+}
+
+/*
+ * Trys to find a client in the specified team.
+ * This function is NOT random, it returns the first
+ * or the cached player (Use Client_GetRandom() instead).
+ *
+ * @param index			Team Index.
+ * @return				Client Index or -1 if no client was found in the specified team.
+ */
+stock int Team_GetAnyClient(int index)
+{
+	static int client_cache[MAX_TEAMS] = {-1, ...};
+	int client;
+
+	if (index > 0) {
+		client = client_cache[index];
+
+		if (client > 0 && client <= MaxClients) {
+
+			if (IsClientInGame(client) && GetClientTeam(client) == index) {
+				return client;
+			}
+		}
+		else {
+			client = -1;
+		}
+	}
+
+	for (client=1; client <= MaxClients; client++) {
+
+		if (!IsClientInGame(client)) {
+			continue;
+		}
+
+		if (GetClientTeam(client) != index) {
+			continue;
+		}
+
+		client_cache[index] = client;
+
+		return client;
+	}
+
+	return -1;
+}

scripting/include/smlib/vehicles.inc

@@ -0,0 +1,137 @@
+#if defined _smlib_vehicles_included
+	#endinput
+#endif
+#define _smlib_vehicles_included
+
+#include <sourcemod>
+#include <sdktools_entinput>
+#include <sdktools_functions>
+#include <smlib/entities>
+
+/**
+ * Returns the vehicle's driver.
+ * If there is no driver in the vehicle, -1 is returned.
+ *
+ * @param vehicle			Entity index.
+ * @return					Client index, or -1 if there is no driver.
+ */
+stock int Vehicle_GetDriver(int vehicle)
+{
+	int m_hVehicle = GetEntPropEnt(vehicle, Prop_Send, "m_hPlayer");
+
+	return m_hVehicle;
+}
+
+/**
+ * Returns whether there is a driver in the vehicle or not.
+ *
+ * @param vehicle			Entity index.
+ * @return					True if the vehicle has a driver, false otherwise
+ */
+stock bool Vehicle_HasDriver(int vehicle)
+{
+	return Vehicle_GetDriver(vehicle) != -1;
+}
+
+/**
+ * Kicks the driver ouf of the vehicle
+ *
+ * @param vehicle			Entity index.
+ * @return					True on success, false otherwise.
+ */
+stock bool Vehicle_ExitDriver(int vehicle)
+{
+	if (!Vehicle_HasDriver(vehicle)) {
+		return false;
+	}
+
+	return AcceptEntityInput(vehicle, "ExitVehicle");
+}
+
+/**
+ * Start's the vehicle's engine
+ *
+ * @param vehicle			Entity index.
+ * @return					True on success, false otherwise.
+ */
+stock bool Vehicle_TurnOn(int vehicle)
+{
+	return AcceptEntityInput(vehicle, "TurnOn");
+}
+
+/**
+ * Shuts down the vehicle's engine
+ *
+ * @param vehicle			Entity index.
+ * @return					True on success, false otherwise.
+ */
+stock bool Vehicle_TurnOff(int vehicle)
+{
+	return AcceptEntityInput(vehicle, "TurnOff");
+}
+
+/**
+ * Locks the vehicle.
+ *
+ * @param vehicle			Entity index.
+ * @return					True on success, false otherwise.
+ */
+stock bool Vehicle_Lock(int vehicle)
+{
+	return AcceptEntityInput(vehicle, "Lock");
+}
+
+/**
+ * Unlocks the vehicle.
+ *
+ * @param vehicle			Entity index.
+ * @return					True on success, false otherwise.
+ */
+stock bool Vehicle_Unlock(int vehicle)
+{
+	return AcceptEntityInput(vehicle, "Unlock");
+}
+
+/**
+ * Returns wether the entity is a valid vehicle or not.
+ *
+ * @param vehicle			Entity index.
+ * @return					True if it is a valid vehicle, false otherwise.
+ */
+stock bool Vehicle_IsValid(int vehicle)
+{
+	if (!Entity_IsValid(vehicle)) {
+		return false;
+	}
+
+	return Entity_ClassNameMatches(vehicle, "prop_vehicle", true);
+}
+
+/**
+ * Reads the vehicle script from a vehicle.
+ * This script contains all the vehicle settings like its speed
+ * and that stuff.
+ *
+ * @param vehicle			Entity index.
+ * @param buffer			String Buffer.
+ * @param size				String Buffer size.
+ * @noreturn
+ */
+stock void Vehicle_GetScript(int vehicle, char[] buffer, int size)
+{
+	GetEntPropString(vehicle, Prop_Data, "m_vehicleScript", buffer, size);
+}
+
+/**
+ * Sets the script of a vehicle.
+ * This script contains all the vehicle settings like its speed
+ * and that stuff.
+ *
+ * @param vehicle			Entity index.
+ * @param buffer			Vehicle Script path.
+ * @noreturn
+ */
+stock void Vehicle_SetScript(int vehicle, char[] script)
+{
+	DispatchKeyValue(vehicle, "vehiclescript", script);
+}

scripting/include/smlib/weapons.inc

@@ -0,0 +1,393 @@
+#if defined _smlib_weapons_included
+	#endinput
+#endif
+#define _smlib_weapons_included
+
+#include <sourcemod>
+#include <sdktools_functions>
+#include <smlib/entities>
+
+#define MAX_WEAPON_OFFSET		64
+#define MAX_WEAPON_SLOTS		6	// hud item selection slots
+#define MAX_WEAPON_POSITIONS	20	// max number of items within a slot
+#define MAX_WEAPONS				48	// Max number of weapons availabl
+#define WEAPON_NOCLIP			-1	// clip sizes set to this tell the weapon it doesn't use a clip
+#define	MAX_AMMO_TYPES			32
+#define MAX_AMMO_SLOTS 			32	// not really slots
+
+#define MAX_WEAPON_STRING		80
+#define MAX_WEAPON_PREFIX		16
+#define MAX_WEAPON_AMMO_NAME	32
+
+/*
+ * Gets the owner (usually a client) of the weapon
+ *
+ * @param weapon		Weapon Entity.
+ * @return				Owner of the weapon or INVALID_ENT_REFERENCE if the weapon has no owner.
+ */
+stock int Weapon_GetOwner(int weapon)
+{
+	return GetEntPropEnt(weapon, Prop_Data, "m_hOwner");
+}
+
+/*
+ * Sets the owner (usually a client) of the weapon
+ *
+ * @param weapon		Weapon Entity.
+ * @param entity		Entity Index.
+ * @noreturn
+ */
+stock void Weapon_SetOwner(int weapon, int entity)
+{
+	SetEntPropEnt(weapon, Prop_Data, "m_hOwner", entity);
+}
+
+/*
+ * Checks whether the entity is a valid weapon or not.
+ *
+ * @param weapon		Weapon Entity.
+ * @return				True if the entity is a valid weapon, false otherwise.
+ */
+stock bool Weapon_IsValid(int weapon)
+{
+	if (!IsValidEdict(weapon)) {
+		return false;
+	}
+
+	return Entity_ClassNameMatches(weapon, "weapon_", true);
+}
+
+/*
+ * Create's a weapon and spawns it in the world at the specified location.
+ *
+ * @param className		Classname String of the weapon to spawn
+ * @param absOrigin		Absolute Origin Vector where to spawn the weapon.
+ * @param absAngles		Absolute Angles Vector.
+ * @return				Weapon Index of the created weapon or INVALID_ENT_REFERENCE on error.
+ */
+stock int Weapon_Create(const char[] className, float absOrigin[3], float absAngles[3])
+{
+	int weapon = Entity_Create(className);
+
+	if (weapon == INVALID_ENT_REFERENCE) {
+		return INVALID_ENT_REFERENCE;
+	}
+
+	Entity_SetAbsOrigin(weapon, absOrigin);
+	Entity_SetAbsAngles(weapon, absAngles);
+
+	DispatchSpawn(weapon);
+
+	return weapon;
+}
+
+/*
+ * Create's a weapon and spawns it in the world at the specified location.
+ *
+ * @param className		Classname String of the weapon to spawn
+ * @param absOrigin		Absolute Origin Vector where to spawn the weapon.
+ * @param absAngles		Absolute Angles Vector.
+ * @return				Weapon Index of the created weapon or INVALID_ENT_REFERENCE on error.
+ */
+stock int Weapon_CreateForOwner(int client, const char[] className)
+{
+	float absOrigin[3], absAngles[3];
+	Entity_GetAbsOrigin(client, absOrigin);
+	Entity_GetAbsAngles(client, absAngles);
+
+	int weapon = Weapon_Create(className, absOrigin, absAngles);
+
+	if (weapon == INVALID_ENT_REFERENCE) {
+		return INVALID_ENT_REFERENCE;
+	}
+
+	Entity_SetOwner(weapon, client);
+
+	return weapon;
+}
+
+/*
+ * Gets the weapon's subtype.
+ * The subtype is only used when a player has multiple weapons of the same type.
+ *
+ * @param weapon		Weapon Entity.
+ * @return				Subtype of the weapon.
+ */
+stock int Weapon_GetSubType(int weapon)
+{
+	return GetEntProp(weapon, Prop_Data, "m_iSubType");
+}
+
+/*
+ * Is the weapon currently reloading ?
+ *
+ * @param weapon		Weapon Entity.
+ * @return				True if weapon is currently reloading, false if not.
+ */
+stock bool Weapon_IsReloading(int weapon)
+{
+	return GetEntProp(weapon, Prop_Data, "m_bInReload") != 0;
+}
+
+/*
+ * Weapon m_iState
+ */
+#define WEAPON_IS_ONTARGET				0x40
+#define WEAPON_NOT_CARRIED				0	// Weapon is on the ground
+#define WEAPON_IS_CARRIED_BY_PLAYER		1	// This client is carrying this weapon.
+#define WEAPON_IS_ACTIVE				2	// This client is carrying this weapon and it's the currently held weapon
+
+/*
+ * Get's the state of the weapon.
+ * This returns whether the weapon is currently carried by a client,
+ * if it is active and if it is on a target.
+ *
+ * @param weapon		Weapon Entity.
+ * @return				Weapon State.
+ */
+stock int Weapon_GetState(int weapon)
+{
+	return GetEntProp(weapon, Prop_Data, "m_iState");
+}
+
+/*
+ * Returns whether the weapon can fire primary ammo under water.
+ *
+ * @param weapon		Weapon Entity.
+ * @return				True or False.
+ */
+stock bool Weapon_FiresUnderWater(int weapon)
+{
+	return GetEntProp(weapon, Prop_Data, "m_bFiresUnderwater") != 0;
+}
+
+/*
+ * Sets if the weapon can fire primary ammo under water.
+ *
+ * @param weapon		Weapon Entity.
+ * @param can			True or False.
+ */
+stock void Weapon_SetFiresUnderWater(int weapon, bool can=true)
+{
+	SetEntProp(weapon, Prop_Data, "m_bFiresUnderwater", can);
+}
+
+/*
+ * Returns whether the weapon can fire secondary ammo under water.
+ *
+ * @param weapon		Weapon Entity.
+ * @return				True or False.
+ */
+stock bool Weapon_FiresUnderWaterAlt(int weapon)
+{
+	return GetEntProp(weapon, Prop_Data, "m_bAltFiresUnderwater") != 0;
+}
+
+/*
+ * Sets if the weapon can fire secondary ammo under water.
+ *
+ * @param weapon		Weapon Entity.
+ * @param can			True or False.
+ */
+stock void Weapon_SetFiresUnderWaterAlt(int weapon, bool can=true)
+{
+	SetEntProp(weapon, Prop_Data, "m_bAltFiresUnderwater", can);
+}
+
+/*
+ * Gets the primary ammo Type (int offset)
+ *
+ * @param weapon		Weapon Entity.
+ * @return				Primary ammo type value.
+ */
+stock int Weapon_GetPrimaryAmmoType(int weapon)
+{
+	return GetEntProp(weapon, Prop_Data, "m_iPrimaryAmmoType");
+}
+
+/*
+ * Sets the primary ammo Type (int offset)
+ *
+ * @param weapon		Weapon Entity.
+ * @param type			Primary ammo type value.
+ */
+stock void Weapon_SetPrimaryAmmoType(int weapon, int type)
+{
+	SetEntProp(weapon, Prop_Data, "m_iPrimaryAmmoType", type);
+}
+
+/*
+ * Gets the secondary ammo Type (int offset)
+ *
+ * @param weapon		Weapon Entity.
+ * @return				Secondary ammo type value.
+ */
+stock int Weapon_GetSecondaryAmmoType(int weapon)
+{
+	return GetEntProp(weapon, Prop_Data, "m_iSecondaryAmmoType");
+}
+
+/*
+ * Sets the secondary ammo Type (int offset)
+ *
+ * @param weapon		Weapon Entity.
+ * @param type			Secondary ammo type value.
+ */
+stock void Weapon_SetSecondaryAmmoType(int weapon, int type)
+{
+	SetEntProp(weapon, Prop_Data, "m_iSecondaryAmmoType", type);
+}
+
+/*
+ * Gets the primary clip count of a weapon.
+ *
+ * @param weapon		Weapon Entity.
+ * @return				Primary Clip count.
+ */
+stock int Weapon_GetPrimaryClip(int weapon)
+{
+	return GetEntProp(weapon, Prop_Data, "m_iClip1");
+}
+
+/*
+ * Sets the primary clip count of a weapon.
+ *
+ * @param weapon		Weapon Entity.
+ * @param value			Clip Count value.
+ */
+stock void Weapon_SetPrimaryClip(int weapon, int value)
+{
+	SetEntProp(weapon, Prop_Data, "m_iClip1", value);
+}
+
+/*
+ * Gets the secondary clip count of a weapon.
+ *
+ * @param weapon		Weapon Entity.
+ * @return				Secondy Clip count.
+ */
+stock int Weapon_GetSecondaryClip(int weapon)
+{
+	return GetEntProp(weapon, Prop_Data, "m_iClip2");
+}
+
+/*
+ * Sets the secondary clip count of a weapon.
+ *
+ * @param weapon		Weapon Entity.
+ * @param value			Clip Count value.
+ */
+stock void Weapon_SetSecondaryClip(int weapon, int value)
+{
+	SetEntProp(weapon, Prop_Data, "m_iClip2", value);
+}
+
+/*
+ * Sets the primary & secondary clip count of a weapon.
+ *
+ * @param weapon		Weapon Entity.
+ * @param primary		Primary Clip Count value.
+ * @param secondary		Primary Clip Count value.
+ */
+stock void Weapon_SetClips(int weapon, int primary, int secondary)
+{
+	Weapon_SetPrimaryClip(weapon, primary);
+	Weapon_SetSecondaryClip(weapon, secondary);
+}
+
+/*
+ * Gets the primary ammo count of a weapon.
+ * This is only used when the weapon is not carried
+ * by a player to give a player ammo when he picks up
+ * the weapon.
+ *
+ * @param weapon		Weapon Entity.
+ * @return				Primary Ammo Count.
+ */
+stock int Weapon_GetPrimaryAmmoCount(int weapon)
+{
+	return GetEntProp(weapon, Prop_Data, "m_iPrimaryAmmoCount");
+}
+
+/*
+ * Sets the primary ammo count of a weapon.
+ * This is only used when the weapon is not carried
+ * by a player to give a player ammo when he picks up
+ * the weapon.
+ *
+ * @param weapon		Weapon Entity.
+ * @param value			Primary Ammo Count.
+ */
+stock void Weapon_SetPrimaryAmmoCount(int weapon, int value)
+{
+	SetEntProp(weapon, Prop_Data, "m_iPrimaryAmmoCount", value);
+}
+
+/*
+ * Gets the secondary ammo count of a weapon.
+ * This is only used when the weapon is not carried
+ * by a player to give a player ammo when he picks up
+ * the weapon.
+ *
+ * @param weapon		Weapon Entity.
+ * @return				Secondary Ammo Count.
+ */
+stock int Weapon_GetSecondaryAmmoCount(int weapon)
+{
+	return GetEntProp(weapon, Prop_Data, "m_iSecondaryAmmoCount");
+}
+
+/*
+ * Sets the secodary ammo count of a weapon.
+ * This is only used when the weapon is not carried
+ * by a player to give a player ammo when he picks up
+ * the weapon.
+ *
+ * @param weapon		Weapon Entity.
+ * @param value			Secondary Ammo Count.
+ */
+stock void Weapon_SetSecondaryAmmoCount(int weapon, int value)
+{
+	SetEntProp(weapon, Prop_Data, "m_iSecondaryAmmoCount", value);
+}
+
+/*
+ * Sets both, the primary & the secondary ammo count of a weapon.
+ * This is only used when the weapon is not carried
+ * by a player to give a player ammo when he picks up
+ * the weapon.
+ *
+ * @param weapon		Weapon Entity.
+ * @value primary		Primary Ammo Count.
+ * @value secondary		Secondary Ammo Count.
+ */
+stock void Weapon_SetAmmoCounts(int weapon, int primary, int secondary)
+{
+	Weapon_SetPrimaryAmmoCount(weapon, primary);
+	Weapon_SetSecondaryAmmoCount(weapon, secondary);
+}
+
+/*
+ * Gets the Model Index of the weapon's view model.
+ *
+ * @param weapon		Weapon Entity.
+ * @return				View Model Index.
+ */
+stock int Weapon_GetViewModelIndex(int weapon)
+{
+	return GetEntProp(weapon, Prop_Data, "m_nViewModelIndex");
+}
+
+/*
+ * Sets the Model Index of the weapon's view model.
+ * You can get the Model Index by precaching a model with PrecacheModel().
+ *
+ * @param weapon		Weapon Entity.
+ * @param index			Model Index.
+ * @noreturn
+ */
+stock void Weapon_SetViewModelIndex(int weapon, int index)
+{
+	SetEntProp(weapon, Prop_Data, "m_nViewModelIndex", index);
+	ChangeEdictState(weapon, FindDataMapInfo(weapon, "m_nViewModelIndex"));
+}

scripting/include/smlib/world.inc

@@ -0,0 +1,16 @@
+#if defined _smlib_world_included
+	#endinput
+#endif
+#define _smlib_world_included
+
+#include <sourcemod>
+
+/*
+ * Gets the world's max size
+ *
+ * @param vec		Vector buffer
+ */
+stock void World_GetMaxs(float vec[3]) {
+
+	GetEntPropVector(0, Prop_Data, "m_WorldMaxs", vec);
+}